Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=hatchling
PYPI_VERIFY_REPO=https://github.com/rthalley/dnspython
PYTHON_COMPAT=( python3_{12..15} )

inherit distutils-r1 pypi

DESCRIPTION="DNS toolkit for Python"
HOMEPAGE="
	https://www.dnspython.org/
	https://github.com/rthalley/dnspython/
	https://pypi.org/project/dnspython/
"

LICENSE="ISC"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~x86 ~x64-macos"
IUSE="dnssec examples https quic"

RDEPEND="
	dnssec? (
		>=dev-python/cryptography-45[${PYTHON_USEDEP}]
	)
	>=dev-python/idna-2.1[${PYTHON_USEDEP}]
	https? (
		>=dev-python/httpx-0.26.0[${PYTHON_USEDEP}]
		>=dev-python/h2-4.1.0[${PYTHON_USEDEP}]
	)
	quic? ( >=dev-python/aioquic-0.9.25[${PYTHON_USEDEP}] )
"
# note: skipping DoH test deps because they require Internet anyway
BDEPEND="
	test? (
		>=dev-python/cryptography-45[${PYTHON_USEDEP}]
		$(python_gen_cond_dep '
			>=dev-python/quart-trio-0.11.0[${PYTHON_USEDEP}]
		' 3.{13..15})
	)
"

EPYTEST_PLUGINS=()
EPYTEST_XDIST=1
distutils_enable_tests pytest

src_prepare() {
	distutils-r1_src_prepare

	sed -i -e '/^\[build-system\]/,/^$/d' -e '/^\[tool\.uv\.build-backend\]/,/^$/d' pyproject.toml || die
	cat >> pyproject.toml <<-EOF || die
		[build-system]
		requires = ["hatchling"]
		build-backend = "hatchling.build"

		[tool.hatch.build.targets.wheel]
		packages = ["dns"]
	EOF
}

python_test() {
	local -x NO_INTERNET=1
	epytest
}

python_install_all() {
	distutils-r1_python_install_all
	if use examples; then
		dodoc -r examples
		docompress -x /usr/share/doc/${PF}/examples
	fi
}