Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
# GNOME 51 mirror ahead of ::gentoo; drop each tag below when ::gentoo reaches this version
# BENTOO-DIVERGENCE: KEYWORDS - ~arm ~loong ~ppc64 dropped: the new papers/glycin deps lack them
# BENTOO-DIVERGENCE: DEPEND - 51.1 is a GTK4 rewrite (papers, gtksourceview:5, libadwaita, glycin, webkit-gtk:6)
# BENTOO-DIVERGENCE: RDEPEND - 51.1 is a GTK4 rewrite; nautilus >=51
# BENTOO-DIVERGENCE: BDEPEND - 51.1 needs blueprint-compiler >=0.19

EAPI=8
inherit gnome.org meson optfeature xdg

DESCRIPTION="A quick previewer for Nautilus, the GNOME file manager"
HOMEPAGE="https://gitlab.gnome.org/GNOME/sushi"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
IUSE="wayland +X"
REQUIRED_USE="|| ( wayland X )"

DEPEND="
	>=app-text/papers-51.0[introspection]
	>=dev-libs/fribidi-1.0.6
	>=dev-libs/glib-2.29.14:2
	>=dev-libs/gobject-introspection-1.82.0-r2:=
	>=dev-libs/gjs-1.40
	>=gui-libs/gtk-4.20:4[introspection,wayland?,X?]
	gui-libs/gtksourceview:5[introspection]
	>=gui-libs/libadwaita-1.8_alpha:1[introspection]
	media-libs/freetype:2
	media-libs/glycin:2[gtk,introspection]
	media-libs/gstreamer:1.0[introspection]
	media-libs/gst-plugins-base:1.0[introspection]
	>=media-libs/harfbuzz-0.9.9:=
	net-libs/webkit-gtk:6=[introspection]
	X? ( x11-libs/libX11 )
"
RDEPEND="${DEPEND}
	>=gnome-base/nautilus-51.0
	media-plugins/gst-plugins-gtk:1.0[wayland?,X?]
"
BDEPEND="
	>=dev-util/blueprint-compiler-0.19.0
	dev-util/glib-utils
	>=sys-devel/gettext-0.19.8
	virtual/pkgconfig
"

src_configure() {
	local emesonargs=(
		$(meson_feature wayland)
		$(meson_feature X X11)
		-Dprofile=default
	)
	meson_src_configure
}

src_compile() {
	local -x GST_PLUGIN_SYSTEM_PATH_1_0=
	meson_src_compile
}

pkg_postinst() {
	optfeature "Support viewing file formats such as generated by LibreOffice" \
		app-office/libreoffice app-office/libreoffice-bin
}