Gentoo Packages

dev-python/astrodendro - 9999 (benzene-overlay)

Search

Install

Install this version:

emerge -a =dev-python/astrodendro-9999

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/astrodendro-9999

Or alternatively:

emerge --autounmask-write -a =dev-python/astrodendro-9999

Package Information

Description:
Python package for computation of astronomical dendrograms
Homepage:
https://dendrograms.readthedocs.io
License:
MIT

Ebuild Details

Version EAPI Keywords Slot
9999 8 ~amd64 ~x86 0
View Raw Ebuild 
# Copyright 2020-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{11..13} )

inherit distutils-r1 virtualx

DESCRIPTION="Python package for computation of astronomical dendrograms"
HOMEPAGE="https://dendrograms.readthedocs.io"

if [[ ${PV} == *9999 ]]; then
	EGIT_REPO_URI="https://github.com/dendrograms/${PN}.git"
	inherit git-r3
else
	inherit pypi
	KEYWORDS="~amd64 ~x86"
fi

LICENSE="MIT"
SLOT="0"

RDEPEND=">=dev-python/numpy-1.24[${PYTHON_USEDEP}]
	>=dev-python/astropy-5[${PYTHON_USEDEP}]
	>=dev-python/h5py-3[${PYTHON_USEDEP}]
	>=dev-python/matplotlib-3.3[${PYTHON_USEDEP}]
"
BDEPEND="dev-python/setuptools-scm[${PYTHON_USEDEP}]
	test? ( || (
		dev-python/pyqt5[${PYTHON_USEDEP},svg]
		dev-python/pyqt6[${PYTHON_USEDEP},svg]
	) )
"

EPYTEST_PLUGINS=()
distutils_enable_tests pytest
distutils_enable_sphinx docs dev-python/sphinx-automodapi dev-python/numpydoc dev-python/aplpy

python_test() {
	virtx epytest
}

Inherited Eclasses

distutils-r1
virtualx
git-r3
pypi

Dependencies

RDEPEND

>=dev-python/numpy-1.24[]
	>=dev-python/astropy-5[]
	>=dev-python/h5py-3[]
	>=dev-python/matplotlib-3.3[]

BDEPEND

dev-python/setuptools-scm[]
	test? ( || (
		dev-python/pyqt5[,svg]
		dev-python/pyqt6[,svg]
	) )