Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{11..14} )

inherit distutils-r1 pypi virtualx

DESCRIPTION="Callback Properties in Python"
HOMEPAGE="https://echo.readthedocs.io"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="qt vue"

RDEPEND="dev-python/numpy[${PYTHON_USEDEP}]
	qt? (
		|| ( dev-python/pyqt6[${PYTHON_USEDEP}] >=dev-python/pyqt5-5.14[${PYTHON_USEDEP}] )
		dev-python/qtpy[${PYTHON_USEDEP}]
	)
	vue? ( dev-python/traitlets[${PYTHON_USEDEP}] )
"
BDEPEND="dev-python/setuptools-scm[${PYTHON_USEDEP}]
	test? (
		|| ( dev-python/pyqt6[${PYTHON_USEDEP}] dev-python/pyqt5[${PYTHON_USEDEP}] )
		dev-python/qtpy[${PYTHON_USEDEP}]
		dev-python/traitlets[${PYTHON_USEDEP}]
	)
"

EPYTEST_PLUGINS=()
distutils_enable_tests pytest
distutils_enable_sphinx doc dev-python/sphinx-automodapi dev-python/numpydoc dev-python/traitlets

python_test() {
	virtx epytest
}