Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{11..13} )

inherit distutils-r1 pypi

DESCRIPTION="Python Socket.IO server and client"
HOMEPAGE="https://python-socketio.readthedocs.io"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="asyncio-client client"

RDEPEND=">=dev-python/bidict-0.21.0[${PYTHON_USEDEP}]
	>=dev-python/python-engineio-4.11.0[${PYTHON_USEDEP}]
	client? (
		>=dev-python/requests-2.21.0[${PYTHON_USEDEP}]
		>=dev-python/websocket-client-0.54.0[${PYTHON_USEDEP}]
	)
	asyncio-client? ( >=dev-python/aiohttp-3.4[${PYTHON_USEDEP}] )
"
BDEPEND="test? (
		dev-python/msgpack[${PYTHON_USEDEP}]
		dev-python/tornado[${PYTHON_USEDEP}]
		dev-python/uvicorn[${PYTHON_USEDEP}]
	)
"

EPYTEST_PLUGINS=( pytest-asyncio )
distutils_enable_tests pytest
distutils_enable_sphinx docs dev-python/furo

EPYTEST_IGNORE=(
	tests/async/test_redis_manager.py
	tests/common/test_redis_manager.py
)