Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{11..13} )

inherit distutils-r1 pypi

DESCRIPTION="Python package for astronomy spectral operations"
HOMEPAGE="https://specutils.readthedocs.org"
SRC_URI+=" doc? (
		https://stsci.box.com/shared/static/28a88k1qfipo4yxc4p4d40v4axtlal8y.fits
		https://data.sdss.org/sas/dr16/sdss/spectro/redux/26/spectra/1323/spec-1323-52797-0012.fits
	)
"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc intersphinx"
PROPERTIES="test_network"
RESTRICT="test
	intersphinx? ( network-sandbox )"
REQUIRED_USE="intersphinx? ( doc )"

RDEPEND=">=dev-python/astropy-7.2[${PYTHON_USEDEP}]
	>=dev-python/asdf-3.3.0[${PYTHON_USEDEP}]
	>=dev-python/asdf-astropy-0.8[${PYTHON_USEDEP}]
	>=dev-python/gwcs-0.25.1[${PYTHON_USEDEP}]
	>=dev-python/scipy-1.14[${PYTHON_USEDEP}]
	>=dev-python/ndcube-2.0[${PYTHON_USEDEP}]
"
BDEPEND="dev-python/setuptools-scm[${PYTHON_USEDEP}]
	doc? (
		${RDEPEND}
		dev-python/sphinx-astropy[${PYTHON_USEDEP},confv2]
		media-gfx/graphviz
	)
	test? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
"

EPYTEST_PLUGINS=( pytest-{asdf-plugin,astropy-header,doctestplus,remotedata} )
distutils_enable_tests pytest
#distutils_enable_sphinx docs dev-python/sphinx-astropy

EPYTEST_DESELECT=(
	# Stuck
	${PN}/tests/test_loaders.py::test_manga_cube
	${PN}/tests/test_loaders.py::test_sdss_spplate
	docs/identify.rst::identify.rst
)

python_prepare_all() {
	use doc && { eapply "${FILESDIR}"/${PN}-2.0.0-doc-use-local-fits.patch; cp "${DISTDIR}"/*.fits "${S}"/docs || die ; }

	distutils-r1_python_prepare_all
}

python_compile_all() {
	if use doc; then
		VARTEXFONTS="${T}"/fonts MPLCONFIGDIR="${T}" PYTHONPATH="${BUILD_DIR}"/install/$(python_get_sitedir) \
			emake "SPHINXOPTS=$(usex intersphinx '' '-D disable_intersphinx=1')" -C docs html
		HTML_DOCS=( docs/_build/html/. )
	fi
}

python_test() {
	use doc && local EPYTEST_IGNORE=( docs/_build )
	epytest --remote-data -o tmp_path_retention_policy=all
}