Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYPI_VERIFY_REPO=https://github.com/fsspec/universal_pathlib
PYTHON_COMPAT=( python3_{11..13} )

inherit distutils-r1 pypi optfeature

DESCRIPTION="pathlib api extended to use fsspec backends"
HOMEPAGE="https://github.com/fsspec/universal_pathlib"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="examples"
PROPERTIES="test_network"
RESTRICT="test"

RDEPEND=">=dev-python/fsspec-2024.5.0[${PYTHON_USEDEP}]
	>=dev-python/pathlib-abc-0.5.1[${PYTHON_USEDEP}]
"
BDEPEND=">=dev-python/setuptools-scm-8[${PYTHON_USEDEP}]
	test? (
		dev-python/cheroot[${PYTHON_USEDEP}]
		dev-python/moto[${PYTHON_USEDEP}]
		dev-python/pydantic-settings[${PYTHON_USEDEP}]
		dev-python/pyftpdlib[${PYTHON_USEDEP}]
		dev-python/requests[${PYTHON_USEDEP}]
		dev-python/s3fs[${PYTHON_USEDEP}]
		dev-python/smbprotocol[${PYTHON_USEDEP}]
		dev-python/webdav4[${PYTHON_USEDEP}]
		dev-python/wsgidav[${PYTHON_USEDEP}]
	)
"

EPYTEST_PLUGINS=()
distutils_enable_tests pytest

EPYTEST_IGNORE=(
	# botocore.exceptions.EndpointConnectionError:
	# Could not connect to the endpoint URL: "http://127.0.0.1:5555/test_bucket"
	upath/tests/implementations/test_s3.py
)

EPYTEST_DESELECT=(
	# gcsfs
	'upath/tests/test_relative.py::test_protocol_storage_options_fs_preserved[gcs-storage_options2-gcs://bucket/foo/bar/baz.txt-gcs://bucket/foo]'
)

python_install_all() {
	if use examples; then
		docompress -x "/usr/share/doc/${PF}/notebooks"
		docinto notebooks
		dodoc -r notebooks/.
	fi

	distutils-r1_python_install_all
}

python_test() {
	epytest -o tmp_path_retention_policy=all
}

pkg_postinst() {
	optfeature "RFC 2397 style data URLs" ">=dev-python/fsspec-2023.12.2"
	optfeature "Google Cloud Storage" dev-python/gcsfs
	optfeature "AWS S3" dev-python/s3fs
	optfeature "SFTP and SSH filesystems" dev-python/paramiko
	optfeature "SMB filesystems" dev-python/smbprotocol
	optfeature "WebDAV-based filesystem on top of HTTP(S)" "dev-python/webdav4[fsspec]"
}