dev-util/debugedit - 5.0 (deso)

Search

Install

Install this version:

emerge -a =dev-util/debugedit-5.0

Package Information

Description:
Create debuginfo and source file distributions
Homepage:
https://sourceware.org/debugedit/
License:
GPL-2+ LGPL-2+

Ebuild Details

Version EAPI Keywords Slot
5.0 8 amd64 arm arm64 hppa ~loong ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux 0
View Raw Ebuild
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit autotools multiprocessing verify-sig

DESCRIPTION="Create debuginfo and source file distributions"
HOMEPAGE="https://sourceware.org/debugedit/"
SRC_URI="
	https://sourceware.org/ftp/debugedit/${PV}/${P}.tar.xz
	verify-sig? ( https://sourceware.org/ftp/debugedit/${PV}/${P}.tar.xz.sig )
"

LICENSE="GPL-2+ LGPL-2+"
SLOT="0"
KEYWORDS="amd64 arm arm64 hppa ~loong ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux"

RDEPEND="
	>=dev-libs/elfutils-0.176-r1
"
DEPEND="${RDEPEND}"
BDEPEND="
	sys-apps/help2man
	virtual/pkgconfig
	verify-sig? (
		sec-keys/openpgp-keys-debugedit
	)
"

VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/debugedit.gpg

PATCHES=(
	"${FILESDIR}"/${P}-readelf.patch
	"${FILESDIR}"/${P}-zero-dir-entry.patch
	"${FILESDIR}"/${P}-hppa.patch
	"${FILESDIR}"/${P}-musl-error.h-fix.patch

	# Upstreamed, remove next release
	"${FILESDIR}"/${P}-musl-1.2.4.patch
	# From upstream, remove next release
	"${FILESDIR}"/${P}-dw-form-strx-support.patch
)

src_prepare() {
	default
	eautoreconf
}

src_test() {
	emake -Onone check TESTSUITEFLAGS="--jobs=$(get_makeopts_jobs)"
}

Inherited Eclasses

Dependencies

DEPEND

	>=dev-libs/elfutils-0.176-r1

RDEPEND

	>=dev-libs/elfutils-0.176-r1

BDEPEND

	sys-apps/help2man
	virtual/pkgconfig
	verify-sig? (
		sec-keys/openpgp-keys-debugedit
	)

Manifest for 5.0

Type File Size Source URLs
DIST debugedit-5.0.tar.xz 164820 bytes https://sourceware.org/ftp/debugedit/5.0/debugedit-5.0.tar.xz
DIST debugedit-5.0.tar.xz.sig 310 bytes https://sourceware.org/ftp/debugedit/5.0/debugedit-5.0.tar.xz.sig