Gentoo Packages

# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

# This ebuild is based off joplin-desktop::gentoo because I wasn't sure what to do with an AppImage.
# My gratitude to whoever wrote that and actually put effort in.

inherit appimage desktop verify-sig xdg

MY_PN="${PN%-bin}"
MY_PV="${PV/_/-}"
APPIMAGE="${MY_PN}-${MY_PV}-x86_64.AppImage"
# _alpha, _beta
[[ -n $(ver_cut 4) ]] && SRC_BRANCH=unstable || SRC_BRANCH=stable

DESCRIPTION="The Krita digital painting application (full version)"
HOMEPAGE="https://krita.org"
SRC_URI="mirror://kde/${SRC_BRANCH}/${MY_PN}/${MY_PV}/${APPIMAGE}
	verify-sig? ( mirror://kde/${SRC_BRANCH}/${MY_PN}/${MY_PV}/${APPIMAGE}.sig )"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS+=" ~amd64"

VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/dmitrykazakov.asc

BDEPEND="verify-sig? ( sec-keys/openpgp-keys-dmitrykazakov )"
RDEPEND="!media-gfx/krita"

src_unpack() {
	verify-sig_src_unpack

	# "appimage-extract" unpacks to current directory.
	mkdir -p "${S}" || die
	cd "${S}" || die
	cp "${DISTDIR}/${APPIMAGE}" "${S}" || die
	chmod +x "${S}/${APPIMAGE}" || die

	"${S}/${APPIMAGE}" --appimage-extract usr/share/icons || die
	"${S}/${APPIMAGE}" --appimage-extract org.kde.krita.desktop || die
}

src_install() {
	# install the icon and menu
	pushd "${S}/squashfs-root" || die
	insinto /usr/share
	doins -r ./usr/share/icons
	domenu ./org.kde.krita.desktop
	popd || die

	# toss the rest and just install the appimage directly
	rm -r "${S}/squashfs-root" || die
	dobin "${S}/${APPIMAGE}"
	dosym -r "/usr/bin/${APPIMAGE}" /usr/bin/krita
}