Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit lomiri

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/apps/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/apps/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.gz"
fi

DESCRIPTION="File Manager application for Lomiri"
HOMEPAGE="https://gitlab.com/ubports/development/apps/${PN}"
LICENSE="GPL-3"
SLOT="0"
RESTRICT="test mirror"

DEPEND="
    dev-qt/qtgui:5
    lomiri-base/lomiri-content-hub
    lomiri-base/lomiri-ui-toolkit
    lomiri-extra/lomiri-ui-extras
    net-fs/samba[client]
"

RDEPEND="${DEPEND}"

BDEPEND="
    dev-build/cmake
    dev-build/cmake-extras
    dev-build/samurai
    dev-qt/qtdeclarative:5
"

S="${WORKDIR}/${PN}-v${PV}"

PATCHES=(
    "${FILESDIR}"/002-fix-plugin-install-dir.patch
    "${FILESDIR}"/003-remove-creator-support.patch
)

src_prepare() {
    # remove ctest from the build
    sed -i '/enable_testing()/d' CMakeLists.txt || die
    cmake_comment_add_subdirectory tests

    lomiri_src_prepare
}

src_configure() {
    local mycmakeargs=(
        -DINSTALL_TESTS="OFF"
        -DCLICK_MODE="OFF"
    )

    lomiri_src_configure
}