Gentoo Packages

# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

LOMIRI_PPA_COMMIT="2.0.5-3"
inherit lomiri

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/apps/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/apps/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.gz
            ${LOMIRI_PPA_URI}"
fi

DESCRIPTION="A terminal app for desktop and mobile devices"
HOMEPAGE="https://gitlab.com/ubports/development/apps/${PN}"
LICENSE="GPL-3"
SLOT="0"
RESTRICT="test mirror"

DEPEND="
    dev-qt/qtgui:5
    dev-qt/qmltermwidget
    lomiri-base/lomiri-ui-toolkit
    lomiri-extra/lomiri-ui-extras
    media-fonts/noto
"

RDEPEND="${DEPEND}"

BDEPEND="
    dev-build/cmake
    dev-build/cmake-extras
    dev-build/samurai
    dev-qt/qtdeclarative:5
"

S="${WORKDIR}/${PN}-v${PV}"

src_prepare() {
    eapply_user

    # remove ctest from the build
    sed -i '/enable_testing()/d' CMakeLists.txt || die
    sed -i '/add_subdirectory(tests)/d' CMakeLists.txt || die

    lomiri_src_prepare
}

src_configure() {
    local mycmakeargs=(
        -DINSTALL_TESTS="OFF"
        -DCLICK_MODE="OFF"
    )

    lomiri_src_configure
}