Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit lomiri multibuild qmake-utils

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/core/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/core/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.gz"
    S="${WORKDIR}/${PN}-v${PV}"
fi

DESCRIPTION="Library to access GSettings from Qt"
HOMEPAGE="https://gitlab.com/ubports/development/core/${PN}"
LICENSE="LGPL-3"
SLOT="0"
IUSE="+qt5 +qt6"
REQUIRED_USE="|| ( qt5 qt6 )"

COMMON_DEPEND="
    dev-libs/glib
    qt5? (
        dev-qt/qtcore:5
        dev-qt/qtdeclarative:5
    )
    qt6? (
        dev-qt/qtbase:6
        dev-qt/qtdeclarative:6
    )
"
DEPEND="${COMMON_DEPEND}"
RDEPEND="${COMMON_DEPEND}"
BDEPEND="
    dev-build/cmake
    dev-build/cmake-extras
    dev-build/samurai
"

_gsettings_qt_variants() {
    MULTIBUILD_VARIANTS=()
    use qt5 && MULTIBUILD_VARIANTS+=( qt5 )
    use qt6 && MULTIBUILD_VARIANTS+=( qt6 )
}

src_configure() {
    local MULTIBUILD_VARIANTS
    _gsettings_qt_variants

    gsettings_qt_configure() {
        local mycmakeargs=( -DBUILD_TESTING="OFF" )

        # qmlplugindump is located via PATH; Gentoo installs it under
        # /usr/lib64/qt{5,6}/bin, which upstream's hardcoded hint misses
        if [[ ${MULTIBUILD_VARIANT} == qt6 ]]; then
            local -x PATH="$(qt6_get_bindir):${PATH}"
            mycmakeargs+=( -DENABLE_QT6="ON" )
        else
            local -x PATH="$(qt5_get_bindir):${PATH}"
            mycmakeargs+=( -DENABLE_QT6="OFF" )
        fi

        cmake_src_configure
    }
    multibuild_foreach_variant gsettings_qt_configure
}

src_compile() {
    local MULTIBUILD_VARIANTS
    _gsettings_qt_variants
    multibuild_foreach_variant cmake_src_compile
}

src_install() {
    local MULTIBUILD_VARIANTS
    _gsettings_qt_variants
    multibuild_foreach_variant cmake_src_install
}