Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit lomiri multibuild

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/core/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/core/${PN}/-/archive/${PV}/${P}.tar.gz"
fi

DESCRIPTION="Provides a service for downloading files while an application is suspended"
HOMEPAGE="https://gitlab.com/ubports/development/core/${PN}"
LICENSE="GPL-3"
SLOT="0"
RESTRICT="test mirror"
IUSE="+qt5 +qt6"
REQUIRED_USE="|| ( qt5 qt6 )"

COMMON_DEPEND="
    dev-cpp/glog:0/2
    dev-libs/boost
    lomiri-base/lomiri-api
    sys-apps/dbus
    sys-apps/systemd
    sys-libs/libapparmor
    qt5? (
        dev-qt/qtdeclarative:5
        dev-qt/qtsql:5
    )
    qt6? (
        dev-qt/qtbase:6
        dev-qt/qtdeclarative:6
        dev-qt/qtscxml:6
    )
"
DEPEND="${COMMON_DEPEND}"
RDEPEND="${COMMON_DEPEND}"
BDEPEND="
    dev-build/cmake
    dev-build/cmake-extras
    dev-build/samurai
"

_ldm_variants() {
    MULTIBUILD_VARIANTS=()
    use qt5 && MULTIBUILD_VARIANTS+=( qt5 )
    use qt6 && MULTIBUILD_VARIANTS+=( qt6 )
}

src_prepare() {
    # remove ctest from the build
    sed -i '/include(CTest)/d' CMakeLists.txt || die

    lomiri_src_prepare
}

src_configure() {
    local MULTIBUILD_VARIANTS
    _ldm_variants

    ldm_configure() {
        local mycmakeargs=(
            -DENABLE_COVERAGE="OFF"
            -DENABLE_DOC="OFF"
            -DENABLE_WERROR="OFF"
        )

        if [[ ${MULTIBUILD_VARIANT} == qt6 ]]; then
            mycmakeargs+=( -DENABLE_QT6="ON" )
        else
            mycmakeargs+=( -DENABLE_QT6="OFF" )
        fi

        cmake_src_configure
    }
    multibuild_foreach_variant ldm_configure
}

src_compile() {
    local MULTIBUILD_VARIANTS
    _ldm_variants
    multibuild_foreach_variant cmake_src_compile
}

src_install() {
    local MULTIBUILD_VARIANTS
    _ldm_variants
    multibuild_foreach_variant cmake_src_install
}