Gentoo Packages

# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit lomiri

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/core/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/core/${PN}/-/archive/${PV}/${P}.tar.gz"
fi

DESCRIPTION="service to prompt for policy kit permissions"
HOMEPAGE="https://gitlab.com/ubports/development/core/${PN}"
LICENSE="GPL-3"
SLOT="0"
RESTRICT="test mirror"

DEPEND="
    sys-auth/polkit
    dev-cpp/properties-cpp
    dev-libs/glib
    x11-libs/libnotify
"

RDEPEND="${DEPEND}"

BDEPEND="
    dev-build/cmake
    dev-build/cmake-extras
    dev-build/samurai
"

PATCHES=(
    "${FILESDIR}"/001-remove-coverage-report.patch
)

src_prepare() {
    # remove ctest from the build
    sed -i '/include(CTest)/d' CMakeLists.txt || die
    cmake_comment_add_subdirectory tests

    lomiri_src_prepare
}

src_install() {
    lomiri_src_install

    # add service links
    dosym /usr/lib/systemd/user/lomiri-polkit-agent.service /usr/lib/systemd/user/lomiri-full-greeter.service.wants/lomiri-polkit-agent.service
    dosym /usr/lib/systemd/user/lomiri-polkit-agent.service /usr/lib/systemd/user/lomiri-full-shell.service.wants/lomiri-polkit-agent.service
    dosym /usr/lib/systemd/user/lomiri-polkit-agent.service /usr/lib/systemd/user/lomiri-greeter.service.wants/lomiri-polkit-agent.service
    dosym /usr/lib/systemd/user/lomiri-polkit-agent.service /usr/lib/systemd/user/lomiri-shell.service.wants/lomiri-polkit-agent.service
}