Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

LOMIRI_PPA_COMMIT="0.3-11"
inherit lomiri

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/core/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/core/${PN}/-/archive/${PV}/${P}.tar.gz
            ${LOMIRI_PPA_URI}"
fi

DESCRIPTION="Lomiri desktop session definition."
HOMEPAGE="https://gitlab.com/ubports/development/core/${PN}"
LICENSE="LGPL-3"
SLOT="0"
RESTRICT="test"

DEPEND=""

RDEPEND="
    ${DEPEND}
    lomiri-base/lomiri
    sys-fs/inotify-tools
    x11-misc/xdg-user-dirs
"

BDEPEND="
    dev-build/cmake
    dev-build/cmake-extras
    dev-build/samurai
"

src_prepare() {
    # remove depend of 'mkcal'
    sed -i "s/^2026_set_mkcal_as_the_alarm_backend_storage.patch/#/" ${DEBIAN_PATCHES_S}/debian/patches/series
    sed -i "s/^2027_set_mkcal_as_the_organizer_backend_storage_patch.patch/#/" ${DEBIAN_PATCHES_S}/debian/patches/series

    lomiri_src_prepare

    # TODO: remove, when lomiri-keyboard is ready
    sed -i "/^Requires=lomiri-keyboard.service/d" systemd/lomiri.service.in
    sed -i "/^Before=lomiri-keyboard.service/d" systemd/lomiri.service.in
}

src_configure() {
    local mycmakeargs=(
        -DENABLE_TOUCH_SESSION="OFF"
    )

    lomiri_src_configure
}