Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

LOMIRI_PPA_COMMIT="0.3-14"
inherit lomiri

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/core/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/core/${PN}/-/archive/${PV}/${P}.tar.gz
            ${LOMIRI_PPA_URI}"
fi

DESCRIPTION="Lomiri desktop session definition."
HOMEPAGE="https://gitlab.com/ubports/development/core/${PN}"
LICENSE="LGPL-3"
SLOT="0"
RESTRICT="test mirror"

DEPEND=""

RDEPEND="
    ${DEPEND}
    lomiri-base/lomiri
    lomiri-extra/lomiri-keyboard
    sys-fs/inotify-tools
    x11-misc/xdg-user-dirs
"

BDEPEND="
    dev-build/cmake
    dev-build/cmake-extras
    dev-build/samurai
"

src_prepare() {
    # mkcal is not packaged; 2028 (sqlite contact backend) builds on the
    # context added by 2026/2027, so disable all three backend patches.
    # TODO: if the sqlite contact backend is ever required, package
    # org.nemomobile.contacts.sqlite, then keep 2028 and instead strip only
    # the *_BACKEND=mkcal lines from lomiri-session.in after the series.
    sed -i "s/^2026_set_mkcal_as_the_alarm_backend_storage.patch/#/" ${DEBIAN_PATCHES_S}/debian/patches/series
    sed -i "s/^2027_set_mkcal_as_the_organizer_backend_storage_patch.patch/#/" ${DEBIAN_PATCHES_S}/debian/patches/series
    sed -i "s/^2028_set_sqlite_as_the_contact_backend_storage.patch/#/" ${DEBIAN_PATCHES_S}/debian/patches/series

    lomiri_src_prepare
}

src_configure() {
    local mycmakeargs=(
        -DENABLE_TOUCH_SESSION="OFF"
    )

    lomiri_src_configure
}