Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit lomiri

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/core/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/core/${PN}/-/archive/${PV}/${P}.tar.gz"
fi

DESCRIPTION="System Settings application for Lomiri"
HOMEPAGE="https://gitlab.com/ubports/development/core/${PN}"
LICENSE="GPL-3"
SLOT="0"
RESTRICT="test mirror"

DEPEND="
    ayatana-indicators/ayatana-indicator-datetime
    ayatana-indicators/ayatana-indicator-power
    dev-libs/glib
    gnome-base/gnome-desktop:3
    lomiri-base/gsettings-qt
    lomiri-base/lomiri-content-hub
    lomiri-base/lomiri-settings-components
    lomiri-base/lomiri-ui-toolkit
    lomiri-base/trust-store
    lomiri-indicators/lomiri-indicator-network
    net-libs/geonames
    sys-apps/accountsservice
    sys-power/upower
"
RDEPEND="${DEPEND}"

BDEPEND="
    dev-build/cmake
    dev-build/cmake-extras
    dev-build/samurai
    dev-qt/qtconcurrent:5
    dev-qt/qtdeclarative:5
"

src_prepare() {
    # disable examples
    cmake_comment_add_subdirectory examples

    # disable 'bluetooth' for now
    cmake_comment_add_subdirectory bluetooth

    # disable 'wifi' fow now
    cmake_comment_add_subdirectory wifi

    # disable mobile settings
    cmake_comment_add_subdirectory flight-mode
    cmake_comment_add_subdirectory gestures
    cmake_comment_add_subdirectory hotspot
    cmake_comment_add_subdirectory orientation-lock

    lomiri_src_prepare
}

src_configure() {
    local mycmakeargs=(
        -DENABLE_TESTS="OFF"
        -DENABLE_UBUNTU_ACCOUNTSSERVICE="OFF"
        -DMODERN_PYTHON_DBUSMOCK="OFF"
        #-DENABLE_LIBDEVICEINFO="ON" # -> use flag
    )

    cmake_src_configure
}