Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit lomiri qmake-utils

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/core/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/core/${PN}/-/archive/${PV}/${PN}-${PV}.tar.gz"
fi

DESCRIPTION="Backend dispatcher service for various mobile phone related operations"
HOMEPAGE="https://gitlab.com/ubports/development/core/${PN}"
LICENSE="GPL-3"
SLOT="0"
RESTRICT="test mirror"

DEPEND="
    ayatana-indicators/ayatana-indicator-messages
    dev-libs/libphonenumber
    dev-qt/qtcore:5
    dev-qt/qtfeedback:5
    dev-qt/qtmultimedia:5
    gnome-base/dconf
    lomiri-base/lomiri-api
    lomiri-base/lomiri-url-dispatcher
    lomiri-extra/lomiri-history-service
    lomiri-extra/lomiri-sounds
    net-libs/telepathy-qt
    net-im/telepathy-mission-control
    gui-libs/libusermetrics
    x11-libs/libnotify
"

RDEPEND="${DEPEND}"

BDEPEND="
	dev-build/cmake-extras
    dev-util/intltool
    dev-build/samurai
    dev-qt/qtdeclarative:5
	virtual/pkgconfig
"

src_configure() {
    # add 'qmake' to PATH
    export PATH="$(qt5_get_bindir):${PATH}"

    # disable tests for now
    local mycmakeargs=(
        -DSKIP_QML_TESTS=ON
    )

    lomiri_src_configure
}

src_install() {
    # remove reference of missing 'ofono-setup.service' -> upstream bug?
    sed -i "/Requires=ofono-setup.service/d" debian/lomiri-telephony-service.lomiri-indicator-telephony-service.user.service || die
    sed -i "/After=ofono-setup.service/d" debian/lomiri-telephony-service.lomiri-indicator-telephony-service.user.service || die

    # install service files
    insinto /usr/lib/systemd/user
    newins debian/lomiri-telephony-service.lomiri-indicator-telephony-service.user.service \
        lomiri-indicator-telephony-service.service
    newins debian/lomiri-telephony-service.lomiri-telephony-service-approver.user.service \
        lomiri-telephony-service-approver.service
    newins debian/lomiri-telephony-service.lomiri-telephony-service-handler.user.service  \
        lomiri-telephony-service-handler.service

    lomiri_src_install
}