Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8
GNOME2_EAUTORECONF="yes"

UVER=ubuntu
UREV=

inherit gnome2 systemd ubuntu-versionator udev

DESCRIPTION="Unity Settings Daemon"
HOMEPAGE="https://launchpad.net/unity-settings-daemon"
SRC_URI="${UURL}.tar.gz"
S="${WORKDIR}/${PN}"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="amd64"
IUSE="+colord debug +i18n +input_devices_wacom nls rfkill +short-touchpad-timeout +udev"
REQUIRED_USE="input_devices_wacom? ( udev )"
RESTRICT="test"

COMMON_DEPEND="
	>=dev-libs/glib-2.39.4:2
	>=gnome-base/gnome-desktop-3.17.92:3=
	>=gnome-base/gsettings-desktop-schemas-3.15.4
	>=media-libs/alsa-lib-1.0.16
	>=media-libs/fontconfig-2.12.6:1.0
	>=media-libs/lcms-2.2:2
	>=media-libs/libcanberra-gtk3-0.25
	>=media-libs/libpulse-2.0[glib]
	>=net-misc/networkmanager-1.0.0
	>=sys-apps/accountsservice-0.6.40:=
	sys-apps/hwdata
	>=sys-power/upower-0.99.1:=
	>=unity-base/gsettings-ubuntu-touch-schemas-0.0.7
	>=x11-libs/gdk-pixbuf-2.23.0:2
	>=x11-libs/gtk+-3.9.10:3
	>=x11-libs/libnotify-0.7.3:=
	x11-libs/libX11
	x11-libs/libXext
	>=x11-libs/libXi-1.2.99.4
	>=x11-libs/libxkbfile-1.1.0
	x11-libs/libXtst

	colord? ( >=x11-misc/colord-1.4.3:= )
	i18n? ( >=app-i18n/ibus-1.5.1 )
	input_devices_wacom? (
		>=gnome-base/librsvg-2.36.2
		>=dev-libs/libwacom-1.1
	)
	udev? (
		>=dev-libs/libgudev-146:=
		virtual/libudev:=
	)
"
RDEPEND="${COMMON_DEPEND}
	gnome-base/dconf
	media-libs/libglvnd
	sys-auth/polkit
	>=x11-libs/cairo-1.14.0
	>=x11-libs/libXfixes-4.0.1
	>=x11-libs/libXrandr-1.2.99.3
	>=x11-libs/pango-1.22.0
	x11-wm/metacity
"
DEPEND="${COMMON_DEPEND}
	x11-misc/xkeyboard-config

	input_devices_wacom? ( x11-drivers/xf86-input-wacom )
"
BDEPEND="
	app-text/docbook-xsl-stylesheets
	dev-libs/libxslt
	dev-util/glib-utils
	dev-util/gperf
	>=dev-util/intltool-0.37.1
	virtual/pkgconfig
"

PATCHES=(
	"${FILESDIR}"/do-not-close-osd-notifications-on-stop.patch
	"${FILESDIR}"/fix-volume-queue-use-after-free.patch
	"${FILESDIR}"/optional-colord-and-wacom.patch
	"${FILESDIR}"/remove-nautilus-support.patch
	"${FILESDIR}"/rename-mutter-dbus-interface-to-muffin.patch
	"${FILESDIR}"/shortcut-alt-app.patch
)

src_prepare() {
	# https://bugzilla.gnome.org/show_bug.cgi?id=621836
	if use short-touchpad-timeout; then
		sed -i \
			-e "/g_ptr_array_add/{s/1.0/0.5/}" \
			plugins/mouse/gsd-mouse-manager.c || die
		grep -Fq 'g_ptr_array_add (args, "0.5");' plugins/mouse/gsd-mouse-manager.c || die
	fi

	# Don't let the forked GL texture size helper fall through on execve failure #
	sed -i \
		-e "s/execve (canary_argv\[0\], canary_argv, canary_env);/& _exit (1);/" \
		gnome-settings-daemon/gsd-rr-config.c || die
	grep -Fq "execve (canary_argv[0], canary_argv, canary_env); _exit (1);" gnome-settings-daemon/gsd-rr-config.c || die

	# Disable all language files as they can be incomplete #
	#  due to being provided by Ubuntu's language-pack packages #
	> po/LINGUAS

	ubuntu-versionator_src_prepare

	# Correct path to unity-settings-daemon executable in upstart and systemd files #
	sed -i \
		-e 's:/usr/lib/unity-settings-daemon:/usr/libexec:g' \
		debian/unity-settings-daemon.user-session.{desktop,upstart} \
		debian/user/unity-settings-daemon.service || die
	! grep -Fq "/usr/lib/unity-settings-daemon" \
		debian/unity-settings-daemon.user-session.{desktop,upstart} \
		debian/user/unity-settings-daemon.service || die

	# Apply the regional formats setting also when started by systemd #
	sed -i \
		-e "s:^ExecStart=/usr/libexec/unity-settings-daemon$:&-localeexec:" \
		debian/user/unity-settings-daemon.service || die
	grep -Fqx "ExecStart=/usr/libexec/unity-settings-daemon-localeexec" \
		debian/user/unity-settings-daemon.service || die

	# Started by the systemd user unit when cinnamon-session runs as a systemd service #
	echo "X-GNOME-HiddenUnderSystemd=true" >> data/unity-settings-daemon.desktop.in.in || die
}

src_configure() {
	local mygnome2args=(
		--disable-static
		--enable-man
		--disable-fcitx
		--disable-packagekit
		$(use_enable colord color)
		$(use_enable debug)
		$(use_enable debug more-warnings)
		$(use_enable i18n ibus)
		$(use_enable nls)
		$(use_enable rfkill)
		--disable-smartcard-support
		$(use_enable udev gudev)
		$(use_enable input_devices_wacom wacom)
	)
	gnome2_src_configure "${mygnome2args[@]}"
}

src_install() {
	gnome2_src_install

	# Install upstart files #
	insinto /usr/share/upstart/xdg/autostart
	newins debian/unity-settings-daemon.user-session.desktop unity-settings-daemon.desktop
	insinto /usr/share/upstart/sessions/
	newins debian/unity-settings-daemon.user-session.upstart unity-settings-daemon.conf

	# Install systemd units #
	systemd_douserunit debian/user/unity-settings-daemon.service
	insinto /usr/share/upstart/systemd-session/upstart
	doins debian/user/unity-settings-daemon.override
}

pkg_postinst() {
	ubuntu-versionator_pkg_postinst
	use rfkill && udev_reload
}

pkg_postrm() {
	gnome2_pkg_postrm
	use rfkill && udev_reload
}