Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

UVER=ubuntu
UREV=

inherit meson xdg ubuntu-versionator

DESCRIPTION="Yaru theme from the Ubuntu Community"
HOMEPAGE="https://discourse.ubuntu.com/c/desktop/theme-refresh"
SRC_URI="${UURL}.tar.xz"

LICENSE="CC-BY-SA-4.0 GPL-2 GPL-3 GPL-3+ LGPL-2.1 LGPL-2.1+ LGPL-3 MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="cinnamon gnome-shell mate +unity xfwm"
RESTRICT="binchecks strip test"

RDEPEND="
	dev-libs/glib:2
	sys-apps/xdg-desktop-portal-gtk
	x11-libs/gtk+:2
	x11-themes/gtk-engines-adwaita
"
BDEPEND="
	dev-libs/glib:2
	dev-libs/libxml2:2
	dev-lang/sassc
"

S="${WORKDIR}/${P}${UVER}"

PATCHES=( "${FILESDIR}"/Remove-light-edges-in-menu-corners.patch )

src_prepare() {
	if use unity; then
		## Don't set window's title bar name alignment ##
		## to center, it prevents title bar name from being ##
		## partially cropped by window's title bar menu ##
		sed -i \
			-e "/UnityDecoration-title-indent/{s/0px/10px/}" \
			-e "/UnityDecoration-title-alignment/d" \
			gtk/src/default/gtk-3.0/apps/_unity7.scss || die

		## Tweak mate-terminal ##
		cat "${FILESDIR}"/mate-terminal.css >> \
			gtk/src/default/gtk-3.0/apps/_mate-terminal.scss || die

		## Tweak nemo ##
		cat "${FILESDIR}"/nemo.css >> \
			gtk/src/default/gtk-3.0/apps/_nemo.scss || die

		## Add Bark and Viridian accent colors ##
		sed -i \
			-e "/value: \[/a 'bark',\n'viridian'," \
			meson_options.txt || die

		## Add Humanity to Inherits (index.theme) ##
		sed -i \
			-e "s/hicolor'/hicolor', 'Humanity'/" \
			icons/src/generate-index-theme.py || die
	fi

	ubuntu-versionator_src_prepare
}

src_configure() {
	local emesonargs=(
		-Dgnome-shell-user-themes-support=$(usex gnome-shell enabled disabled)
		-Dgtk=true
		-Dgtksourceview=true
		-Dicons=true
		-Dmetacity=true
		-Dsessions=false
		-Dsounds=true
		$(meson_use cinnamon )
		$(meson_use cinnamon cinnamon-dark )
		$(meson_use cinnamon cinnamon-shell )
		$(meson_use gnome-shell )
		$(meson_use gnome-shell gnome-shell-gresource )
		$(meson_use mate )
		$(meson_use mate mate-dark )
		$(meson_use unity ubuntu-unity )
		$(meson_use xfwm xfwm4 )
	)
	meson_src_configure
}

src_install() {
	meson_src_install

	## Add Yaru-dark drop-down menu icon as "go-down-symbolic" ##
	insinto /usr/share/icons
	doins -r "${FILESDIR}"/go-down-icon/Yaru-dark
	local accent
	for accent in ${ED}/usr/share/icons/Yaru-*-dark; do
		dosym -r /usr/share/icons/Yaru-dark/scalable/actions/go-down-symbolic.svg \
			"${accent/${ED}}"/scalable/actions/go-down-symbolic.svg
	done
}