Gentoo Packages

# Copyright 2023-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit unpacker desktop xdg

DESCRIPTION="Opensource IDE For Exploring and Testing Api's"
HOMEPAGE="https://www.usebruno.com/"
SRC_URI="
	amd64? ( https://github.com/usebruno/bruno/releases/download/v${PV}/bruno_${PV}_amd64_linux.deb )
	arm64? ( https://github.com/usebruno/bruno/releases/download/v${PV}/bruno_${PV}_arm64_linux.deb )
"

S="${WORKDIR}"
LICENSE="MIT"
SLOT="0"
KEYWORDS="-* ~amd64 ~arm64"

RDEPEND="
	app-accessibility/at-spi2-core:2
	dev-libs/expat
	dev-libs/glib:2
	dev-libs/nspr
	dev-libs/nss
	media-libs/alsa-lib
	media-libs/mesa
	net-print/cups
	sys-apps/dbus
	virtual/libudev
	x11-libs/cairo
	x11-libs/gtk+:3[X,cups]
	x11-libs/libX11
	x11-libs/libXcomposite
	x11-libs/libXdamage
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXrandr
	x11-libs/libxcb
	x11-libs/libxkbcommon[X]
	x11-libs/pango
"

RESTRICT="strip"

QA_PREBUILT="opt/Bruno/*"

src_install() {
	insinto /opt/Bruno
	doins -r "${S}"/opt/Bruno/.
	fperms +x /opt/Bruno/bruno
	fperms +x /opt/Bruno/chrome-sandbox
	fperms +x /opt/Bruno/chrome_crashpad_handler

	domenu "${S}"/usr/share/applications/bruno.desktop

	for size in 16 24 32 48 64 128 256 512 1024; do
		doicon -s ${size} "${S}"/usr/share/icons/hicolor/${size}x${size}/apps/bruno.png
	done
}