Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit shell-completion go-env go-module toolchain-funcs

# update this on every bump
GIT_COMMIT=88096ef00576baf72a9cb45caa45c0544c40e0a7

DESCRIPTION="the command line binary for docker"
HOMEPAGE="https://www.docker.com/"
SRC_URI="https://github.com/docker/cli/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/cli-${PV}"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
IUSE="selinux"

RDEPEND="selinux? ( sec-policy/selinux-docker )"
BDEPEND="
	dev-go/go-md2man
	>=dev-lang/go-1.26.3
"

RESTRICT="installsources strip test"

src_prepare() {
	default
	sed -i 's@dockerd\?\.exe@@g' contrib/completion/bash/docker || die
	ln -s vendor.mod go.mod || die
	ln -s vendor.sum go.sum || die
}

src_compile() {
	export DISABLE_WARN_OUTSIDE_CONTAINER=1

	myemakeargs=(
		VERSION="${PV}"
		GITCOMMIT="${GIT_COMMIT}"
	)

	emake "${myemakeargs[@]}" dynbinary
	tc-env_build go-env_run emake "${myemakeargs[@]}" manpages
}

src_install() {
	dobin build/docker
	doman man/man?/*
	dobashcomp contrib/completion/bash/docker
	bashcomp_alias docker dockerd
	dofishcomp contrib/completion/fish/docker.fish
	dozshcomp contrib/completion/zsh/_*
}

pkg_postinst() {
	has_version "app-containers/docker-buildx" && return
	ewarn "the 'docker build' command is deprecated and will be removed in a"
	ewarn "future release. If you need this functionality, install"
	ewarn "app-containers/docker-buildx."
}