Gentoo Packages

app-emulation/libspectrum - 1.5.0-r1 (gentoo)

Search

Install

Install this version:

emerge -a =app-emulation/libspectrum-1.5.0-r1

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =app-emulation/libspectrum-1.5.0-r1

Or alternatively:

emerge --autounmask-write -a =app-emulation/libspectrum-1.5.0-r1

Package Information

Description:
Spectrum emulation library
Homepage:
https://fuse-emulator.sourceforge.net/libspectrum.php
License:
GPL-2

Ebuild Details

Version EAPI Keywords Slot
1.5.0-r1 8 ~amd64 ~ppc ~riscv ~x86 0/9
View Raw Ebuild 
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit autotools

DESCRIPTION="Spectrum emulation library"
HOMEPAGE="https://fuse-emulator.sourceforge.net/libspectrum.php"
SRC_URI="https://downloads.sourceforge.net/fuse-emulator/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0/9"
KEYWORDS="~amd64 ~ppc ~riscv ~x86"
IUSE="audiofile bzip2 gcrypt zlib"

RDEPEND="dev-libs/glib:2
	audiofile? ( >=media-libs/audiofile-0.3.6 )
	bzip2? ( >=app-arch/bzip2-1.0 )
	gcrypt? ( dev-libs/libgcrypt:0 )
	zlib? ( virtual/zlib:= )"
DEPEND="${RDEPEND}"
BDEPEND="dev-lang/perl
	virtual/pkgconfig"

PATCHES=(
	"${FILESDIR}"/remove-local-prefix.patch
)

src_prepare() {
	default
	eautoreconf
}

src_configure() {
	local myconf=(
		$(use_with audiofile libaudiofile)
		$(use_with bzip2)
		$(use_with gcrypt libgcrypt)
		$(use_with zlib)
	)
	econf "${myconf[@]}"
}

src_test() {
	# check only builds test executable but doesn't run it
	emake check
	./test/test || die
}

src_install() {
	default
	dodoc doc/*.txt *.txt
	find "${ED}" -type f -name "*.la" -delete || die
}

USE Flags

Manage flags for this package: euse -i <flag> -p app-emulation/libspectrum | euse -E <flag> -p app-emulation/libspectrum | euse -D <flag> -p app-emulation/libspectrum

Global/Standard Flags

audiofile
bzip2
gcrypt
zlib

Inherited Eclasses

autotools

Dependencies

DEPEND

dev-libs/glib:2
	audiofile? ( >=media-libs/audiofile-0.3.6 )
	bzip2? ( >=app-arch/bzip2-1.0 )
	gcrypt? ( dev-libs/libgcrypt:0 )
	zlib? ( virtual/zlib:= )

RDEPEND

dev-libs/glib:2
	audiofile? ( >=media-libs/audiofile-0.3.6 )
	bzip2? ( >=app-arch/bzip2-1.0 )
	gcrypt? ( dev-libs/libgcrypt:0 )
	zlib? ( virtual/zlib:= )

BDEPEND

dev-lang/perl
	virtual/pkgconfig