app-misc/libdatovka - 0.8.0 (gentoo)

Search

Install

Install this version:

emerge -a =app-misc/libdatovka-0.8.0

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =app-misc/libdatovka-0.8.0

Or alternatively:

emerge --autounmask-write -a =app-misc/libdatovka-0.8.0

Package Information

Description:
Client library for accessing ISDS SOAP services
Homepage:
https://www.datovka.cz/cs/pages/libdatovka.html
License:
LGPL-3

Ebuild Details

Version EAPI Keywords Slot
0.8.0 8 ~amd64 ~x86 0/11
View Raw Ebuild
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DESCRIPTION="Client library for accessing ISDS SOAP services"
HOMEPAGE="https://www.datovka.cz/cs/pages/libdatovka.html"
SRC_URI="https://datovka.nic.cz/${PN}/${P}.tar.xz"

LICENSE="LGPL-3"
SLOT="0/11"
KEYWORDS="~amd64 ~x86"

IUSE="+curl debug doc nls openssl test"
RESTRICT="!test? ( test )"

RDEPEND="
	dev-libs/expat
	dev-libs/libxml2:=
	curl? ( net-misc/curl[ssl] )
	doc? (
		app-text/docbook-xsl-stylesheets
		dev-libs/libxslt
	)
	openssl? ( dev-libs/openssl:= )
	!openssl? (
		|| (
			app-crypt/gnupg
			app-crypt/freepg
		)
		app-crypt/gpgme:=
		dev-libs/libgcrypt:=
	)"
DEPEND="${RDEPEND}
	test? ( net-libs/gnutls )"
BDEPEND="
	virtual/pkgconfig
	nls? ( sys-devel/gettext )"

PATCHES=(
	"${FILESDIR}"/${P}-musl-strptime-yday.patch
)

src_prepare() {
	default

	# musl accepts any locale name (cs_CZ.ISO8859-2 stays UTF-8) and its
	# iconv substitutes unrepresentable characters instead of failing
	if use elibc_musl; then
		sed -i '/^TESTS = /,/[^\\]$/s/ utf82locale\$(EXEEXT)//' test/offline/Makefile.in || die
	fi
}

src_configure() {
	local myeconfargs=(
		--disable-fatalwarnings
		$(use_with curl libcurl)
		$(use_enable curl curlreauthorizationbug)
		$(use_enable doc)
		$(use_enable debug)
		$(use_enable nls)
		$(use_enable openssl openssl-backend)
		$(use_enable test)
	)
	econf "${myeconfargs[@]}"
}

src_install() {
	default
	find "${ED}" -name '*.la' -delete || die
}

USE Flags

Manage flags for this package: euse -i <flag> -p app-misc/libdatovka | euse -E <flag> -p app-misc/libdatovka | euse -D <flag> -p app-misc/libdatovka

Global/Standard Flags

curl
❓ Default: Enabled (+)
doc
nls

Dependencies

DEPEND

	dev-libs/expat
	dev-libs/libxml2:=
	curl? ( net-misc/curl[ssl] )
	doc? (
		app-text/docbook-xsl-stylesheets
		dev-libs/libxslt
	)
	openssl? ( dev-libs/openssl:= )
	!openssl? (
		|| (
			app-crypt/gnupg
			app-crypt/freepg
		)
		app-crypt/gpgme:=
		dev-libs/libgcrypt:=
	)
	test? ( net-libs/gnutls )

RDEPEND

	dev-libs/expat
	dev-libs/libxml2:=
	curl? ( net-misc/curl[ssl] )
	doc? (
		app-text/docbook-xsl-stylesheets
		dev-libs/libxslt
	)
	openssl? ( dev-libs/openssl:= )
	!openssl? (
		|| (
			app-crypt/gnupg
			app-crypt/freepg
		)
		app-crypt/gpgme:=
		dev-libs/libgcrypt:=
	)

BDEPEND

	virtual/pkgconfig
	nls? ( sys-devel/gettext )

Manifest for 0.8.0

Type File Size Source URLs
DIST libdatovka-0.8.0.tar.xz 737664 bytes https://datovka.nic.cz/libdatovka/libdatovka-0.8.0.tar.xz