Gentoo Packages

Search

Install

Install this version:

emerge -a =app-text/xchm-1.37

Package Information

Description:: Utility for viewing Compiled HTML Help (CHM) files
Homepage:: https://github.com/rzvncj/xCHM/
License:: GPL-2+

Ebuild Details

Version	EAPI	Keywords	Slot
1.37	8	amd64 ppc ~riscv x86	0

View Raw Ebuild

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

WX_GTK_VER="3.2-gtk3"

inherit desktop wxwidgets xdg-utils

DESCRIPTION="Utility for viewing Compiled HTML Help (CHM) files"
HOMEPAGE="https://github.com/rzvncj/xCHM/"
SRC_URI="https://github.com/rzvncj/xCHM/releases/download/${PV}/${P}.tar.gz"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="amd64 ppc ~riscv x86"
IUSE="nls"

RDEPEND=">=dev-libs/chmlib-0.36
	x11-libs/wxGTK:${WX_GTK_VER}=[X]
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}"
BDEPEND="nls? ( sys-devel/gettext )"

src_configure() {
	setup-wxwidgets
	econf $(use_enable nls)
}

src_install() {
	default

	domenu "${FILESDIR}"/xchm.desktop
	insinto /usr/share/mime/packages
	doins "${FILESDIR}"/xchm.xml
}

pkg_postinst() {
	xdg_desktop_database_update
	xdg_icon_cache_update
	xdg_mimeinfo_database_update
}

pkg_postrm() {
	xdg_desktop_database_update
	xdg_icon_cache_update
	xdg_mimeinfo_database_update
}

USE Flags

Manage flags for this package: euse -i <flag> -p app-text/xchm | euse -E <flag> -p app-text/xchm | euse -D <flag> -p app-text/xchm

Global/Standard Flags

nls

Inherited Eclasses

desktop

wxwidgets

xdg-utils

Dependencies

DEPEND

>=dev-libs/chmlib-0.36
	x11-libs/wxGTK:3.2-gtk3=[X]
	nls? ( virtual/libintl )

RDEPEND

>=dev-libs/chmlib-0.36
	x11-libs/wxGTK:3.2-gtk3=[X]
	nls? ( virtual/libintl )

BDEPEND

nls? ( sys-devel/gettext )

Manifest for 1.37

Type	File	Size	Source URLs
DIST	xchm-1.37.tar.gz	893765 bytes	https://github.com/rzvncj/xCHM/releases/download/1.37/xchm-1.37.tar.gz

app-text/xchm - 1.37 (gentoo)