Gentoo Packages

dev-debug/gprofng-gui - 9999 (gentoo)

Search

Install

Install this version:

emerge -a =dev-debug/gprofng-gui-9999

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-debug/gprofng-gui-9999

Or alternatively:

emerge --autounmask-write -a =dev-debug/gprofng-gui-9999

Package Information

Description:
Full-fledged graphical interface to operate gprofng
Homepage:
https://www.gnu.org/software/gprofng-gui/
License:
GPL-3+

Ebuild Details

Version EAPI Keywords Slot
9999 8 ~amd64 0
View Raw Ebuild 
# Copyright 2024-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit java-pkg-2 xdg

DESCRIPTION="Full-fledged graphical interface to operate gprofng"
HOMEPAGE="https://www.gnu.org/software/gprofng-gui/"

if [[ ${PV} == 9999 ]] ; then
	EGIT_REPO_URI="https://git.savannah.gnu.org/git/gprofng-gui.git"
	inherit autotools git-r3
else
	SRC_URI="mirror://gnu/gprofng-gui/${P}.tar.gz"
	S="${WORKDIR}/${P}"

	KEYWORDS="~amd64"
fi

LICENSE="GPL-3+"
SLOT="0"

DEPEND=">=virtual/jdk-1.8:*"
RDEPEND="
	sys-devel/binutils:*[gprofng(-)]
	>=virtual/jre-1.8:*
"

src_prepare() {
	default

	mkdir "${WORKDIR}"/build || die

	[[ ${PV} == 9999 ]] && eautoreconf

	java-pkg-2_src_prepare
}

src_configure() {
	cd "${WORKDIR}"/build || die
	ECONF_SOURCE="${S}" econf
}

src_compile() {
	emake -C "${WORKDIR}"/build
}

src_install() {
	einstalldocs
	emake -C "${WORKDIR}"/build DESTDIR="${D}" install
}

Inherited Eclasses

java-pkg-2
xdg
autotools
git-r3

Applicable Mirrors

Mirror Name URLs
gnu

Dependencies

DEPEND

>=virtual/jdk-1.8:*

RDEPEND

	sys-devel/binutils:*[gprofng(-)]
	>=virtual/jre-1.8:*