Gentoo Packages

Search

Install

Install this version:

emerge -a =dev-libs/ayatana-ido-0.10.4-r1

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-libs/ayatana-ido-0.10.4-r1

Or alternatively:

emerge --autounmask-write -a =dev-libs/ayatana-ido-0.10.4-r1

Package Information

Description:: Ayatana Application Indicators (Shared Library)
Homepage:: https://github.com/AyatanaIndicators/ayatana-ido
License:: LGPL-2.1 LGPL-3 GPL-3

Ebuild Details

Version	EAPI	Keywords	Slot
0.10.4-r1	8	~alpha amd64 arm arm64 ~loong ppc ppc64 ~riscv ~sparc x86	0

View Raw Ebuild

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8
VALA_USE_DEPEND="vapigen"

inherit cmake vala virtualx

DESCRIPTION="Ayatana Application Indicators (Shared Library)"
HOMEPAGE="https://github.com/AyatanaIndicators/ayatana-ido"
SRC_URI="https://github.com/AyatanaIndicators/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="LGPL-2.1 LGPL-3 GPL-3"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~loong ppc ppc64 ~riscv ~sparc x86"

IUSE="test"
RESTRICT="!test? ( test )"

RDEPEND="
	>=dev-libs/glib-2.58:2
	>=dev-libs/gobject-introspection-1.82.0-r2
	>=x11-libs/gtk+-3.24:3[introspection]
"
DEPEND="
	${RDEPEND}
	x11-base/xorg-proto
"
BDEPEND="
	$(vala_depend)
	dev-util/glib-utils
	test? ( dev-cpp/gtest )
"

src_prepare() {
	cmake_src_prepare
	vala_setup
}

src_configure() {
	local mycmakeargs+=(
		-DVALA_COMPILER="${VALAC}"
		-DVAPI_GEN="${VAPIGEN}"
		-DENABLE_TESTS="$(usex test)"
	)
	cmake_src_configure
}

src_test() {
	virtx cmake_src_test
}

USE Flags

Manage flags for this package: euse -i <flag> -p dev-libs/ayatana-ido | euse -E <flag> -p dev-libs/ayatana-ido | euse -D <flag> -p dev-libs/ayatana-ido

Global/Standard Flags

test

Inherited Eclasses

cmake

vala

virtualx

Dependencies

DEPEND

	
	>=dev-libs/glib-2.58:2
	>=dev-libs/gobject-introspection-1.82.0-r2
	>=x11-libs/gtk+-3.24:3[introspection]

	x11-base/xorg-proto

RDEPEND

	>=dev-libs/glib-2.58:2
	>=dev-libs/gobject-introspection-1.82.0-r2
	>=x11-libs/gtk+-3.24:3[introspection]

BDEPEND

	$(vala_depend)
	dev-util/glib-utils
	test? ( dev-cpp/gtest )

dev-libs/ayatana-ido - 0.10.4-r1 (gentoo)