Gentoo Packages

Search

Install

Install this version:

emerge -a =dev-libs/libgudev-238-r2

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-libs/libgudev-238-r2

Or alternatively:

emerge --autounmask-write -a =dev-libs/libgudev-238-r2

Package Information

Description:: GObject bindings for libudev
Homepage:: https://wiki.gnome.org/Projects/libgudev
License:: LGPL-2.1+

Ebuild Details

Version	EAPI	Keywords	Slot
238-r2	7	~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86	0/0

View Raw Ebuild

# Copyright 2015-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit meson-multilib

DESCRIPTION="GObject bindings for libudev"
HOMEPAGE="https://wiki.gnome.org/Projects/libgudev"
SRC_URI="https://download.gnome.org/sources/libgudev/${PV}/${P}.tar.xz"

LICENSE="LGPL-2.1+"
SLOT="0/0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
IUSE="introspection test"
RESTRICT="!test? ( test )"

RDEPEND="
	>=dev-libs/glib-2.38.0:2[${MULTILIB_USEDEP}]
	>=virtual/libudev-251:=[sticky-tags(+),${MULTILIB_USEDEP}]
	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )
"
DEPEND="${RDEPEND}
	test? ( dev-util/umockdev[${MULTILIB_USEDEP}] )
"
BDEPEND="
	dev-util/glib-utils
	virtual/pkgconfig
"

PATCHES=(
	"${FILESDIR}"/${PV}-clang18-export-dynamic.patch #926350
	"${FILESDIR}"/238-systemd-259-tests.patch #971296
)

multilib_src_configure() {
	local emesonargs=(
		$(meson_native_use_feature introspection)
		-Dgtk_doc=false
		$(meson_feature test tests)
		-Dvapi=disabled
	)
	meson_src_configure
}

src_test() {
	# libsandbox interferes somehow.
	# There are no access violations, but tests fail.
	# https://bugs.gentoo.org/805449
	local -x SANDBOX_ON=0
	meson-multilib_src_test
}

USE Flags

Manage flags for this package: euse -i <flag> -p dev-libs/libgudev | euse -E <flag> -p dev-libs/libgudev | euse -D <flag> -p dev-libs/libgudev

Global/Standard Flags

introspection

test

Inherited Eclasses

meson-multilib

Dependencies

DEPEND

	>=dev-libs/glib-2.38.0:2[]
	>=virtual/libudev-251:=[sticky-tags(+),]
	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )

	test? ( dev-util/umockdev[] )

RDEPEND

	>=dev-libs/glib-2.38.0:2[]
	>=virtual/libudev-251:=[sticky-tags(+),]
	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )

BDEPEND

	dev-util/glib-utils
	virtual/pkgconfig

dev-libs/libgudev - 238-r2 (gentoo)