Gentoo Packages

Search

Install

Install this version:

emerge -a =dev-libs/qtkeychain-0.16.0

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-libs/qtkeychain-0.16.0

Or alternatively:

emerge --autounmask-write -a =dev-libs/qtkeychain-0.16.0

Package Information

Description:: Qt API for storing passwords securely
Homepage:: https://github.com/frankosterfeld/qtkeychain
License:: BSD-2

Ebuild Details

Version	EAPI	Keywords	Slot
0.16.0	8	~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86	0/1

View Raw Ebuild

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit cmake

DESCRIPTION="Qt API for storing passwords securely"
HOMEPAGE="https://github.com/frankosterfeld/qtkeychain"

if [[ ${PV} != *9999* ]]; then
	SRC_URI="https://github.com/frankosterfeld/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
else
	inherit git-r3
	EGIT_REPO_URI="https://github.com/frankosterfeld/${PN}.git"
fi

LICENSE="BSD-2"
SLOT="0/1"
IUSE="keyring test"

# tests require DBus
RESTRICT="test !test? ( test )"

RDEPEND="
	dev-qt/qtbase:6[dbus]
	keyring? (
		app-crypt/libsecret
		dev-libs/glib:2
	)
"
DEPEND="${RDEPEND}"
BDEPEND="dev-qt/qttools:6[linguist]"

DOCS=( ChangeLog ReadMe.md )

src_configure() {
	local mycmakeargs=(
		-DECM_MKSPECS_INSTALL_DIR="${EPREFIX}"/usr/$(get_libdir)/qt6/mkspecs
		-DBUILD_QTQUICK_DEMO=OFF
		-DBUILD_TEST_APPLICATION=OFF
		-DBUILD_TRANSLATIONS=ON
		-DBUILD_WITH_QT6=ON
		-DLIBSECRET_SUPPORT=$(usex keyring)
		-DBUILD_TESTING=$(usex test)
	)

	cmake_src_configure
}

USE Flags

Manage flags for this package: euse -i <flag> -p dev-libs/qtkeychain | euse -E <flag> -p dev-libs/qtkeychain | euse -D <flag> -p dev-libs/qtkeychain

Global/Standard Flags

keyring

test

Inherited Eclasses

cmake

git-r3

Dependencies

DEPEND

	dev-qt/qtbase:6[dbus]
	keyring? (
		app-crypt/libsecret
		dev-libs/glib:2
	)

RDEPEND

	dev-qt/qtbase:6[dbus]
	keyring? (
		app-crypt/libsecret
		dev-libs/glib:2
	)

BDEPEND

dev-qt/qttools:6[linguist]

Manifest for 0.16.0

Type	File	Size	Source URLs
DIST	qtkeychain-0.16.0.tar.gz	63901 bytes	https://github.com/frankosterfeld/qtkeychain/archive/refs/tags/0.16.0.tar.gz

dev-libs/qtkeychain - 0.16.0 (gentoo)