Gentoo Packages

dev-libs/spdlog - 9999 (gentoo)

Search

Install

Install this version:

emerge -a =dev-libs/spdlog-9999

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-libs/spdlog-9999

Or alternatively:

emerge --autounmask-write -a =dev-libs/spdlog-9999

Package Information

Description:
Fast C++ logging library
Homepage:
https://github.com/gabime/spdlog
License:
MIT

Ebuild Details

Version EAPI Keywords Slot
9999 8 ~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 0/$(ver_cut 1-2)
View Raw Ebuild 
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit cmake-multilib

DESCRIPTION="Fast C++ logging library"
HOMEPAGE="https://github.com/gabime/spdlog"

if [[ ${PV} == *9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/gabime/${PN}"
else
	SRC_URI="https://github.com/gabime/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
fi

LICENSE="MIT"
SLOT="0/$(ver_cut 1-2)"
IUSE="test"
RESTRICT="!test? ( test )"

BDEPEND="
	virtual/pkgconfig
	test? (
		>=dev-cpp/catch-3.4.0
	)
"
DEPEND="
	dev-libs/libfmt:=[${MULTILIB_USEDEP}]
"
RDEPEND="${DEPEND}"

PATCHES=(
	"${FILESDIR}/${PN}-force_external_fmt.patch"
)

src_prepare() {
	cmake_src_prepare
	rm -r include/spdlog/fmt/bundled || die "Failed to delete bundled libfmt"
}

multilib_src_configure() {
	local mycmakeargs=(
		-DSPDLOG_BUILD_BENCH=no
		-DSPDLOG_BUILD_EXAMPLE=no
		-DSPDLOG_FMT_EXTERNAL=yes
		-DSPDLOG_BUILD_SHARED=yes
		-DSPDLOG_BUILD_TESTS=$(usex test)
	)

	cmake_src_configure
}

USE Flags

Manage flags for this package: euse -i <flag> -p dev-libs/spdlog | euse -E <flag> -p dev-libs/spdlog | euse -D <flag> -p dev-libs/spdlog

Global/Standard Flags

test

Inherited Eclasses

cmake-multilib
git-r3

Dependencies

DEPEND

	dev-libs/libfmt:=[]

RDEPEND

	dev-libs/libfmt:=[]

BDEPEND

	virtual/pkgconfig
	test? (
		>=dev-cpp/catch-3.4.0
	)