dev-ml/eqaf - 0.10 (gentoo)

Search

Install

Install this version:

emerge -a =dev-ml/eqaf-0.10

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-ml/eqaf-0.10

Or alternatively:

emerge --autounmask-write -a =dev-ml/eqaf-0.10

Package Information

Description:
Constant time equal function to avoid timing attacks in OCaml
Homepage:
https://github.com/mirage/eqaf
License:
MIT

Ebuild Details

Version EAPI Keywords Slot
0.10 8 ~amd64 ~arm64 ~x86 0/0.10
View Raw Ebuild
# Copyright 2025-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit dune multiprocessing

DESCRIPTION="Constant time equal function to avoid timing attacks in OCaml"
HOMEPAGE="https://github.com/mirage/eqaf"
SRC_URI="https://github.com/mirage/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"

LICENSE="MIT"
SLOT="0/${PV}"
KEYWORDS="~amd64 ~arm64 ~x86"
IUSE="+ocamlopt test"
RESTRICT="!test? ( test )"

DOCS=( README.md CHANGES.md )

RDEPEND="
	dev-ml/cstruct:=[ocamlopt?]
"
DEPEND="
	${RDEPEND}
	test? (
		dev-ml/ocaml-base64
		dev-ml/alcotest
		dev-ml/fmt
	)
"

src_prepare() {
	default
	# requires unpackaged crowbar
	rm -rf fuzz || die
}

src_test() {
	if has_version -b ">=dev-lang/ocaml-5.5"; then
		# test/test_branch.ml fails to build with OCaml 5.5
		# https://github.com/mirage/eqaf/issues/50
		edune exec --display=short -j $(get_makeopts_jobs) test/test.exe
	else
		dune_src_test
	fi
}

USE Flags

Manage flags for this package: euse -i <flag> -p dev-ml/eqaf | euse -E <flag> -p dev-ml/eqaf | euse -D <flag> -p dev-ml/eqaf

Global/Standard Flags

ocamlopt
❓ Default: Enabled (+)

Inherited Eclasses

Dependencies

DEPEND

	
	dev-ml/cstruct:=[ocamlopt?]

	test? (
		dev-ml/ocaml-base64
		dev-ml/alcotest
		dev-ml/fmt
	)

RDEPEND

	dev-ml/cstruct:=[ocamlopt?]

Manifest for 0.10

Type File Size Source URLs
DIST eqaf-0.10.gh.tar.gz 33311 bytes https://github.com/mirage/eqaf/archive/v0.10.tar.gz