Gentoo Packages

# Copyright 2024-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{12..14} )

inherit distutils-r1 pypi

DESCRIPTION="Reimplementation of the Python stdlib smtpd.py based on asyncio"
HOMEPAGE="
	https://aiosmtpd.aio-libs.org/
	https://github.com/aio-libs/aiosmtpd
	https://pypi.org/project/aiosmtpd/
"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="amd64 arm arm64 ~loong ppc ppc64 ~riscv ~sparc x86"

RDEPEND="
	>=dev-python/atpublic-4.0[${PYTHON_USEDEP}]
	>=dev-python/attrs-23.2.0[${PYTHON_USEDEP}]
"
BDEPEND="
	test? (
		dev-python/pkg-resources[${PYTHON_USEDEP}]
	)
"

EPYTEST_DESELECT=(
	# Needs dev-vcs/git
	aiosmtpd/qa/test_0packaging.py::TestVersion
)

EPYTEST_PLUGINS=( pytest-mock )
distutils_enable_tests pytest

python_prepare_all() {
	sed -i -e '/--cov=/d' pytest.ini || die

	distutils-r1_python_prepare_all
}

python_test() {
	local EPYTEST_DESELECT=()
	case ${EPYTHON} in
		python3.1[34])
			EPYTEST_DESELECT+=(
				# https://github.com/aio-libs/aiosmtpd/issues/403
				aiosmtpd/tests/test_server.py::TestUnthreaded::test_unixsocket
			)
			;;
	esac

	epytest
}