Gentoo Packages

dev-python/commonmark - 0.9.2 (gentoo)

Search

Install

Install this version:

emerge -a =dev-python/commonmark-0.9.2

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/commonmark-0.9.2

Or alternatively:

emerge --autounmask-write -a =dev-python/commonmark-0.9.2

Package Information

Description:
Python parser for the CommonMark Markdown spec
Homepage:
https://pypi.org/project/commonmark/ https://github.com/readthedocs/commonmark.py/
License:
BSD

Ebuild Details

Version EAPI Keywords Slot
0.9.2 8 ~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 0
View Raw Ebuild 
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{11..14} pypy3_11 )

inherit distutils-r1 pypi

DESCRIPTION="Python parser for the CommonMark Markdown spec"
HOMEPAGE="
	https://pypi.org/project/commonmark/
	https://github.com/readthedocs/commonmark.py/
"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="test"
RESTRICT="!test? ( test )"

BDEPEND="
	test? (
		>=dev-python/hypothesis-3.7.1[${PYTHON_USEDEP}]
	)
"

python_test() {
	local -x PYTHONIOENCODING='utf8'
	"${EPYTHON}" commonmark/tests/run_spec_tests.py || die
}

src_prepare() {
	default
	# Fix file collision with app-text/cmark, see bug #627034
	sed -i -e "s:'cmark\( = commonmark.cmark\:main'\):'cmark.py\1:" \
		setup.py || die
}

pkg_postinst() {
	ewarn "/usr/bin/cmark has been renamed to /usr/bin/cmark.py due file"
	ewarn "collision with app-text/cmark (see bug #627034)"
}

USE Flags

Manage flags for this package: euse -i <flag> -p dev-python/commonmark | euse -E <flag> -p dev-python/commonmark | euse -D <flag> -p dev-python/commonmark

Global/Standard Flags

test

Inherited Eclasses

distutils-r1
pypi

Dependencies

BDEPEND

	test? (
		>=dev-python/hypothesis-3.7.1[]
	)