Gentoo Packages

dev-python/executing - 2.3.0 (gentoo)

Search

Install

Install this version:

emerge -a =dev-python/executing-2.3.0

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/executing-2.3.0

Or alternatively:

emerge --autounmask-write -a =dev-python/executing-2.3.0

Package Information

Description:
Get information about what a Python frame is currently doing
Homepage:
https://github.com/alexmojaki/executing/ https://pypi.org/project/executing/
License:
MIT

Ebuild Details

Version EAPI Keywords Slot
2.3.0 8 ~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos 0
View Raw Ebuild 
# Copyright 2020-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_TESTED=( python3_{12..14} )
PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" python3_15 )

inherit distutils-r1 optfeature pypi

DESCRIPTION="Get information about what a Python frame is currently doing"
HOMEPAGE="
	https://github.com/alexmojaki/executing/
	https://pypi.org/project/executing/
"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"

BDEPEND="
	dev-python/setuptools-scm[${PYTHON_USEDEP}]
	test? (
		>=dev-python/asttokens-2.1.0[${PYTHON_USEDEP}]
		dev-python/littleutils[${PYTHON_USEDEP}]
		dev-python/rich[${PYTHON_USEDEP}]
	)
"

EPYTEST_PLUGINS=()
distutils_enable_tests pytest

python_test() {
	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
		einfo "Skipping tests on ${EPYTHON}"
		return
	fi

	local EPYTEST_DESELECT=()
	if ! has_version "dev-python/ipython[${PYTHON_USEDEP}]"; then
		EPYTEST_DESELECT+=(
			tests/test_ipython.py
		)
	fi

	epytest
}

pkg_postinst() {
	optfeature "getting node's source code" dev-python/asttokens
}

Inherited Eclasses

distutils-r1
optfeature
pypi

Dependencies

BDEPEND

	dev-python/setuptools-scm[]
	test? (
		>=dev-python/asttokens-2.1.0[]
		dev-python/littleutils[]
		dev-python/rich[]
	)