Gentoo Packages

dev-python/jsonpatch - 1.34 (gentoo)

Search

Install

Install this version:

emerge -a =dev-python/jsonpatch-1.34

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/jsonpatch-1.34

Or alternatively:

emerge --autounmask-write -a =dev-python/jsonpatch-1.34

Package Information

Description:
Apply JSON-Patches like http://tools.ietf.org/html/draft-pbryan-json-patch-04
Homepage:
https://github.com/stefankoegl/python-json-patch/ https://pypi.org/project/jsonpatch/
License:
BSD

Ebuild Details

Version EAPI Keywords Slot
1.34 8 ~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86 0
View Raw Ebuild 
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{12..15} )

inherit distutils-r1

MY_P=python-json-patch-${PV}
DESCRIPTION="Apply JSON-Patches like http://tools.ietf.org/html/draft-pbryan-json-patch-04"
HOMEPAGE="
	https://github.com/stefankoegl/python-json-patch/
	https://pypi.org/project/jsonpatch/
"
SRC_URI="
	https://github.com/stefankoegl/python-json-patch/archive/v${PV}.tar.gz
		-> ${MY_P}.gh.tar.gz
"
S=${WORKDIR}/${MY_P}

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
IUSE="test"
RESTRICT="!test? ( test )"

RDEPEND="
	>=dev-python/jsonpointer-1.9[${PYTHON_USEDEP}]
"
BDEPEND="
	test? (
		${RDEPEND}
		dev-python/hypothesis[${PYTHON_USEDEP}]
	)
"

src_prepare() {
	distutils-r1_src_prepare

	# https://github.com/stefankoegl/python-json-patch/pull/159
	sed -e 's/unittest.makeSuite/unittest.defaultTestLoader.loadTestsFromTestCase/' \
		-i ext_tests.py tests.py
}

python_test() {
	"${EPYTHON}" tests.py || die "Tests of tests.py fail with ${EPYTHON}"
	"${EPYTHON}" ext_tests.py || die "Tests of ext_tests.py fail with ${EPYTHON}"
	"${EPYTHON}" property_tests.py || die "Tests of property_tests.py fail with ${EPYTHON}"
}

USE Flags

Manage flags for this package: euse -i <flag> -p dev-python/jsonpatch | euse -E <flag> -p dev-python/jsonpatch | euse -D <flag> -p dev-python/jsonpatch

Global/Standard Flags

test

Inherited Eclasses

distutils-r1

Dependencies

RDEPEND

	>=dev-python/jsonpointer-1.9[]

BDEPEND

	test? (
		
	>=dev-python/jsonpointer-1.9[]

		dev-python/hypothesis[]
	)

Manifest for 1.34

Type File Size Source URLs
DIST python-json-patch-1.34.gh.tar.gz 39356 bytes https://github.com/stefankoegl/python-json-patch/archive/v1.34.tar.gz