Gentoo Packages

Search

Install

Install this version:

emerge -a =dev-python/pika-1.4.1

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/pika-1.4.1

Or alternatively:

emerge --autounmask-write -a =dev-python/pika-1.4.1

Package Information

Description:: Pure-Python implementation of the AMQP
Homepage:: https://pika.readthedocs.io/ https://github.com/pika/pika/ https://pypi.org/project/pika/
License:: MPL-2.0

Ebuild Details

Version	EAPI	Keywords	Slot
1.4.1	8	~amd64 ~arm64 ~x86	0

View Raw Ebuild

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{11..14} )
inherit distutils-r1

DESCRIPTION="Pure-Python implementation of the AMQP"
HOMEPAGE="
	https://pika.readthedocs.io/
	https://github.com/pika/pika/
	https://pypi.org/project/pika/
"
SRC_URI="https://github.com/pika/pika/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"

LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"
IUSE="test"
RESTRICT="test !test? ( test )"
PROPERTIES="test_network"

BDEPEND="
	test? (
		dev-python/twisted[${PYTHON_USEDEP}]
		dev-python/tornado[${PYTHON_USEDEP}]
		net-misc/rabbitmq-server
	)
"

EPYTEST_PLUGINS=( pytest-timeout )
EPYTEST_XDIST=1
distutils_enable_tests pytest

python_test() {
	epytest -k "not test_with_gevent"
}

src_test() {
	einfo "Starting rabbitmq"
	local -x RABBITMQ_LOG_BASE="${T}/rabbitmq/log"
	local -x RABBITMQ_MNESIA_BASE="${T}/rabbitmq/mnesia"
	local -x RABBITMQ_LOGS="${T}/rabbitmq.log"
	local -x RABBITMQ_PID_FILE="${T}/rabbitmq.pid"
	local -x RABBITMQ_ENABLED_PLUGINS_FILE="${T}/rabbitmq/enabled_plugins"
	/usr/libexec/rabbitmq/rabbitmq-server -p 5672:5672 &

	einfo "Waiting for rabbitmq to fully load"
	while ! { echo >/dev/tcp/localhost/5672 ; } &> /dev/null; do
		sleep 1
	done
	einfo "rabbitmq is ready"

	distutils-r1_src_test

	einfo "Stopping rabbitmq"
	kill "$(<"${RABBITMQ_PID_FILE}")" || die
}

USE Flags

Manage flags for this package: euse -i <flag> -p dev-python/pika | euse -E <flag> -p dev-python/pika | euse -D <flag> -p dev-python/pika

Global/Standard Flags

test

Inherited Eclasses

distutils-r1

Dependencies

BDEPEND

	test? (
		dev-python/twisted[]
		dev-python/tornado[]
		net-misc/rabbitmq-server
	)

Manifest for 1.4.1

Type	File	Size	Source URLs
DIST	pika-1.4.1.gh.tar.gz	337544 bytes	https://github.com/pika/pika/archive/1.4.1.tar.gz

dev-python/pika - 1.4.1 (gentoo)