Gentoo Packages

Search

Install

Install this version:

emerge -a =dev-python/propcache-0.5.2

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/propcache-0.5.2

Or alternatively:

emerge --autounmask-write -a =dev-python/propcache-0.5.2

Package Information

Description:: Accelerated property cache
Homepage:: https://github.com/aio-libs/propcache/ https://pypi.org/project/propcache/
License:: Apache-2.0

Ebuild Details

Version	EAPI	Keywords	Slot
0.5.2	8	~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86	0

View Raw Ebuild

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=standalone
PYPI_VERIFY_REPO=https://github.com/aio-libs/propcache
PYTHON_COMPAT=( python3_{11..14} python3_{13,14}t pypy3_11 )

inherit distutils-r1 pypi

DESCRIPTION="Accelerated property cache"
HOMEPAGE="
	https://github.com/aio-libs/propcache/
	https://pypi.org/project/propcache/
"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="+native-extensions"

BDEPEND="
	native-extensions? (
		dev-python/cython[${PYTHON_USEDEP}]
	)
	dev-python/expandvars[${PYTHON_USEDEP}]
	dev-python/setuptools[${PYTHON_USEDEP}]
"

EPYTEST_PLUGINS=()
distutils_enable_tests pytest

python_compile() {
	local -x PROPCACHE_NO_EXTENSIONS=0
	if ! use native-extensions || [[ ${EPYTHON} != python* ]]; then
		PROPCACHE_NO_EXTENSIONS=1
	fi
	distutils-r1_python_compile
}

python_test() {
	local EPYTEST_IGNORE=(
		tests/test_benchmarks.py
	)

	local opts=()
	if ! use native-extensions || [[ ${EPYTHON} != python* ]]; then
		opts+=( --no-c-extensions )
	fi

	rm -rf propcache || die
	epytest -o addopts= "${opts[@]}"
}

USE Flags

Manage flags for this package: euse -i <flag> -p dev-python/propcache | euse -E <flag> -p dev-python/propcache | euse -D <flag> -p dev-python/propcache

Global/Standard Flags

native-extensions

Inherited Eclasses

distutils-r1

pypi

Dependencies

BDEPEND

	native-extensions? (
		dev-python/cython[]
	)
	dev-python/expandvars[]
	dev-python/setuptools[]

dev-python/propcache - 0.5.2 (gentoo)