Gentoo Packages

dev-python/pyamg - 5.3.0-r1 (gentoo)

Search

Install

Install this version:

emerge -a =dev-python/pyamg-5.3.0-r1

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/pyamg-5.3.0-r1

Or alternatively:

emerge --autounmask-write -a =dev-python/pyamg-5.3.0-r1

Package Information

Description:
Algebraic multigrid solvers in Python
Homepage:
https://github.com/pyamg/pyamg/ https://pypi.org/project/pyamg/
License:
BSD

Ebuild Details

Version EAPI Keywords Slot
5.3.0-r1 8 ~amd64 0
View Raw Ebuild 
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{12..14} )

inherit distutils-r1

DESCRIPTION="Algebraic multigrid solvers in Python"
HOMEPAGE="
	https://github.com/pyamg/pyamg/
	https://pypi.org/project/pyamg/
"
SRC_URI="
	https://github.com/pyamg/pyamg/archive/v${PV}.tar.gz
		-> ${P}.gh.tar.gz
"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64"

DEPEND="
	dev-python/pybind11[${PYTHON_USEDEP}]
	dev-python/numpy[${PYTHON_USEDEP}]
"
RDEPEND="
	dev-python/cppheaderparser[${PYTHON_USEDEP}]
	dev-python/numpy[${PYTHON_USEDEP}]
	dev-python/pyyaml[${PYTHON_USEDEP}]
	>=dev-python/scipy-1.11.0[${PYTHON_USEDEP}]
"
BDEPEND="
	${DEPEND}
	>=dev-python/setuptools-scm-7.0.0[${PYTHON_USEDEP}]
	test? (
		dev-python/matplotlib[${PYTHON_USEDEP}]
	)
"

EPYTEST_PLUGINS=()
distutils_enable_tests pytest

src_prepare() {
	local PATCHES=(
		# https://github.com/pyamg/pyamg/commit/9f8299bcf1141e627503c3f208eda413bc1e28e6
		"${FILESDIR}/${P}-backport.patch"
	)

	distutils-r1_src_prepare

	# invalid with >=setuptools-scm-9
	sed -i -e '/version =/d' setup.cfg || die
}

python_test() {
	cd "${T}" || die
	epytest --pyargs pyamg
}

Inherited Eclasses

distutils-r1

Dependencies

DEPEND

	dev-python/pybind11[]
	dev-python/numpy[]

RDEPEND

	dev-python/cppheaderparser[]
	dev-python/numpy[]
	dev-python/pyyaml[]
	>=dev-python/scipy-1.11.0[]

BDEPEND

	
	dev-python/pybind11[]
	dev-python/numpy[]

	>=dev-python/setuptools-scm-7.0.0[]
	test? (
		dev-python/matplotlib[]
	)