Gentoo Packages

dev-python/pypdf - 6.10.2 (gentoo)

Search

Install

Install this version:

emerge -a =dev-python/pypdf-6.10.2

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/pypdf-6.10.2

Or alternatively:

emerge --autounmask-write -a =dev-python/pypdf-6.10.2

Package Information

Description:
Python library to work with PDF files
Homepage:
https://pypi.org/project/pypdf/ https://github.com/py-pdf/pypdf/
License:
BSD

Ebuild Details

Version EAPI Keywords Slot
6.10.2 8 ~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86 0
View Raw Ebuild 
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=flit
PYTHON_COMPAT=( python3_{11..14} )

inherit distutils-r1

SAMPLE_COMMIT=65e82ed36c1efd9bd7172a35c8dcfd6e18aabfb2
DESCRIPTION="Python library to work with PDF files"
HOMEPAGE="
	https://pypi.org/project/pypdf/
	https://github.com/py-pdf/pypdf/
"
SRC_URI="
	https://github.com/py-pdf/pypdf/archive/${PV}.tar.gz
		-> ${P}.gh.tar.gz
	test? (
		https://github.com/py-pdf/sample-files/archive/${SAMPLE_COMMIT}.tar.gz
			-> ${PN}-sample-files-${SAMPLE_COMMIT}.gh.tar.gz
	)
"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"

BDEPEND="
	test? (
		dev-python/cryptography[${PYTHON_USEDEP}]
		>=dev-python/pillow-8.0.0[jpeg,jpeg2k,tiff,zlib,${PYTHON_USEDEP}]
		dev-python/pyyaml[${PYTHON_USEDEP}]
		media-libs/jbig2dec[png]
	)
"

EPYTEST_PLUGINS=( pytest-timeout )
EPYTEST_XDIST=1
distutils_enable_tests pytest

src_unpack() {
	default
	if use test; then
		mv "sample-files-${SAMPLE_COMMIT}"/* "${S}"/sample-files/ || die
	fi
}

python_test() {
	epytest -o addopts= -m "not enable_socket"
}

Inherited Eclasses

distutils-r1

Dependencies

BDEPEND

	test? (
		dev-python/cryptography[]
		>=dev-python/pillow-8.0.0[jpeg,jpeg2k,tiff,zlib,]
		dev-python/pyyaml[]
		media-libs/jbig2dec[png]
	)

Manifest for 6.10.2

Type File Size Source URLs
DIST pypdf-6.10.2.gh.tar.gz 8408895 bytes https://github.com/py-pdf/pypdf/archive/6.10.2.tar.gz
DIST pypdf-sample-files-65e82ed36c1efd9bd7172a35c8dcfd6e18aabfb2.gh.tar.gz 11748256 bytes https://github.com/py-pdf/sample-files/archive/65e82ed36c1efd9bd7172a35c8dcfd6e18aabfb2.tar.gz