Gentoo Packages

dev-python/pypugjs - 6.0.2 (gentoo)

Search

Install

Install this version:

emerge -a =dev-python/pypugjs-6.0.2

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/pypugjs-6.0.2

Or alternatively:

emerge --autounmask-write -a =dev-python/pypugjs-6.0.2

Package Information

Description:
Pug (Jade) syntax adapter for Django, Jinja2 and Mako templates
Homepage:
https://github.com/kakulukia/pypugjs/ https://pypi.org/project/pypugjs/
License:
MIT

Ebuild Details

Version EAPI Keywords Slot
6.0.2 8 ~amd64 ~arm64 ~riscv 0
View Raw Ebuild 
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=poetry
PYTHON_COMPAT=( python3_{12..14} )

inherit distutils-r1 optfeature

DESCRIPTION="Pug (Jade) syntax adapter for Django, Jinja2 and Mako templates"
HOMEPAGE="
	https://github.com/kakulukia/pypugjs/
	https://pypi.org/project/pypugjs/
"
SRC_URI="
	https://github.com/kakulukia/pypugjs/archive/v${PV}.tar.gz
		-> ${P}.gh.tar.gz
"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~riscv"

RDEPEND="
	>=dev-python/six-1.17.0[${PYTHON_USEDEP}]
	>=dev-python/charset-normalizer-3.4.4[${PYTHON_USEDEP}]
"
BDEPEND="
	test? (
		>=dev-python/django-4.2.25[${PYTHON_USEDEP}]
		>=dev-python/flask-2.3.3[${PYTHON_USEDEP}]
		>=dev-python/jinja2-3.1.6[${PYTHON_USEDEP}]
		>=dev-python/mako-1.3.10[${PYTHON_USEDEP}]
		>=dev-python/tornado-6.5.2[${PYTHON_USEDEP}]
	)
"

EPYTEST_PLUGINS=( pytest-asyncio )
distutils_enable_tests pytest

src_prepare() {
	# poetry nonsense
	sed -i -e 's:\^:>=:' pyproject.toml || die
	distutils-r1_src_prepare
}

pkg_postinst() {
	optfeature "converting to Django output" dev-python/django
	optfeature "converting to Jinja2 output" dev-python/jinja2
	optfeature "converting to Mako output" dev-python/mako
	optfeature "converting to Tornado output" dev-python/tornado
}

Inherited Eclasses

distutils-r1
optfeature

Dependencies

RDEPEND

	>=dev-python/six-1.17.0[]
	>=dev-python/charset-normalizer-3.4.4[]

BDEPEND

	test? (
		>=dev-python/django-4.2.25[]
		>=dev-python/flask-2.3.3[]
		>=dev-python/jinja2-3.1.6[]
		>=dev-python/mako-1.3.10[]
		>=dev-python/tornado-6.5.2[]
	)

Manifest for 6.0.2

Type File Size Source URLs
DIST pypugjs-6.0.2.gh.tar.gz 70319 bytes https://github.com/kakulukia/pypugjs/archive/v6.0.2.tar.gz