dev-python/python-box - 8.0.0 (gentoo)

Search

Install

Install this version:

emerge -a =dev-python/python-box-8.0.0

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/python-box-8.0.0

Or alternatively:

emerge --autounmask-write -a =dev-python/python-box-8.0.0

Package Information

Description:
Python dictionaries with advanced dot notation access
Homepage:
https://github.com/cdgriffith/Box/ https://pypi.org/project/python-box/
License:
MIT

Ebuild Details

Version EAPI Keywords Slot
8.0.0 8 ~amd64 ~arm64 0
View Raw Ebuild
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{12..15} )

inherit distutils-r1

MY_P=Box-${PV}
DESCRIPTION="Python dictionaries with advanced dot notation access"
HOMEPAGE="
	https://github.com/cdgriffith/Box/
	https://pypi.org/project/python-box/
"
SRC_URI="
	https://github.com/cdgriffith/Box/archive/${PV}.tar.gz
		-> ${MY_P}.gh.tar.gz
"
S=${WORKDIR}/${MY_P}

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64"
IUSE="+native-extensions"

RDEPEND="
	dev-python/msgpack[${PYTHON_USEDEP}]
	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
	dev-python/tomli-w[${PYTHON_USEDEP}]
"
BDEPEND="
	native-extensions? (
		dev-python/cython[${PYTHON_USEDEP}]
	)
"

EPYTEST_PLUGINS=()
distutils_enable_tests pytest

EPYTEST_DESELECT=(
	# require unpackaged 'toon' (probably from git too)
	test/test_box.py::TestBox::test_toon_files
	test/test_box.py::TestBox::test_toon_from_toon_with_box_args
	test/test_box.py::TestBox::test_toon_strings
	test/test_box_list.py::TestBoxList::test_toon_files
	test/test_box_list.py::TestBoxList::test_toon_strings
	test/test_edge_cases.py::TestConverters::test_toon_roundtrip_and_type_mismatch
)

src_prepare() {
	if ! use native-extensions; then
		# a cheap hack, extensions are auto-disabled if Cython.Build
		# is not importable
		> Cython.py || die
	fi

	distutils-r1_src_prepare
}

python_test() {
	rm -rf box || die
	epytest
}

USE Flags

Manage flags for this package: euse -i <flag> -p dev-python/python-box | euse -E <flag> -p dev-python/python-box | euse -D <flag> -p dev-python/python-box

Global/Standard Flags

native-extensions
❓ Default: Enabled (+)

Inherited Eclasses

Dependencies

RDEPEND

	dev-python/msgpack[]
	dev-python/ruamel-yaml[]
	dev-python/tomli-w[]

BDEPEND

	native-extensions? (
		dev-python/cython[]
	)

Manifest for 8.0.0

Type File Size Source URLs
DIST Box-8.0.0.gh.tar.gz 235670 bytes https://github.com/cdgriffith/Box/archive/8.0.0.tar.gz