Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=hatchling
PYPI_VERIFY_REPO=https://github.com/pyapp-kit/superqt
PYTHON_COMPAT=( python3_{11..14} )

inherit distutils-r1 pypi virtualx

DESCRIPTION="Missing widgets and components for PyQt/PySide"
HOMEPAGE="
	https://github.com/pyapp-kit/superqt
	https://pypi.org/project/superqt/
"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm64"

RDEPEND="
	>=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
	>=dev-python/qtpy-2.4.0[${PYTHON_USEDEP}]
	>=dev-python/typing-extensions-4.12.0[${PYTHON_USEDEP}]
"

BDEPEND="
	dev-python/hatch-vcs[${PYTHON_USEDEP}]
	test? (
		dev-python/numpy[${PYTHON_USEDEP}]
		dev-python/pytest-qt[${PYTHON_USEDEP}]
	)
"

EPYTEST_IGNORE=(
	# pint and pyconify not packaged
	tests/test_quantity.py
	tests/test_iconify.py
)

EPYTEST_DESELECT=(
	# fails in the sandbox, but works outside of it
	tests/test_eliding_label.py::test_wrapped_eliding_label
)

distutils_enable_tests pytest

python_test() {
	virtx distutils-r1_python_test
}