Install this version:
emerge -a =dev-python/watchdog-7.0.0If this version is masked, you can unmask it using the autounmask tool or standard emerge options:
autounmask =dev-python/watchdog-7.0.0Or alternatively:
emerge --autounmask-write -a =dev-python/watchdog-7.0.0| Version | EAPI | Keywords | Slot |
|---|---|---|---|
| 7.0.0 | 8 | ~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 | 0 |
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{12..15} python3_{14,15}t )
inherit distutils-r1 optfeature pypi
DESCRIPTION="Python API and shell utilities to monitor file system events"
HOMEPAGE="
https://github.com/gorakhargosh/watchdog/
https://pypi.org/project/watchdog/
"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
RDEPEND="
dev-python/pyyaml[${PYTHON_USEDEP}]
"
EPYTEST_PLUGINS=( pytest-timeout )
EPYTEST_XDIST=1
distutils_enable_tests pytest
python_test() {
local EPYTEST_DESELECT=(
# known flaky
tests/test_emitter.py::test_close
# requires root powers via sudo (yes, seriously)
tests/test_inotify_buffer.py::test_unmount_watched_directory_filesystem
)
# there's a test opening 2048 files
ulimit -n 4096 || die
epytest -o addopts=
}
pkg_postinst() {
optfeature "Bash completion" dev-python/argcomplete
}