Gentoo Packages

dev-scheme/guile-git - 0.11.0 (gentoo)

Search

Install

Install this version:

emerge -a =dev-scheme/guile-git-0.11.0

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-scheme/guile-git-0.11.0

Or alternatively:

emerge --autounmask-write -a =dev-scheme/guile-git-0.11.0

Package Information

Description:
Guile bindings of git
Homepage:
https://gitlab.com/guile-git/guile-git/
License:
LGPL-3+

Ebuild Details

Version EAPI Keywords Slot
0.11.0 8 ~amd64 ~x86 0
View Raw Ebuild 
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

GUILE_COMPAT=( 3-0 )

inherit autotools guile

DESCRIPTION="Guile bindings of git"
HOMEPAGE="https://gitlab.com/guile-git/guile-git/"

if [[ "${PV}" == *9999* ]] ; then
	inherit git-r3

	EGIT_REPO_URI="https://gitlab.com/${PN}/${PN}"
else
	SRC_URI="https://gitlab.com/${PN}/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
	S="${WORKDIR}/${PN}-v${PV}"

	KEYWORDS="~amd64 ~x86"
fi

LICENSE="LGPL-3+"
SLOT="0"
REQUIRED_USE="${GUILE_REQUIRED_USE}"

RDEPEND="
	${GUILE_DEPS}
	>=dev-libs/libgit2-1.8.0:=
	>=dev-scheme/bytestructures-2.0.2-r100[${GUILE_USEDEP}]
"
DEPEND="
	${RDEPEND}
"
BDEPEND="
	virtual/pkgconfig
"

src_prepare() {
	guile_src_prepare

	# network sandbox + ssh configuration
	sed -i -e '/tests\/clone.scm/d' Makefile.am || die

	eautoreconf
}

src_test() {
	guile_foreach_impl emake VERBOSE="1" check
}

Inherited Eclasses

autotools
guile
git-r3

Dependencies

DEPEND

	
	
	>=dev-libs/libgit2-1.8.0:=
	>=dev-scheme/bytestructures-2.0.2-r100[]

RDEPEND

	
	>=dev-libs/libgit2-1.8.0:=
	>=dev-scheme/bytestructures-2.0.2-r100[]

BDEPEND

	virtual/pkgconfig

Manifest for 0.11.0

Type File Size Source URLs
DIST guile-git-v0.11.0.tar.bz2 110689 bytes https://gitlab.com/guile-git//-/archive/v0.11.0/-v.tar.bz2