Gentoo Packages

dev-scheme/owl-lisp - 9999 (gentoo)

Search

Install

Install this version:

emerge -a =dev-scheme/owl-lisp-9999

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-scheme/owl-lisp-9999

Or alternatively:

emerge --autounmask-write -a =dev-scheme/owl-lisp-9999

Package Information

Description:
Purely functional dialect of Scheme
Homepage:
https://haltp.org/posts/owl.html https://gitlab.com/owl-lisp/owl/
License:
MIT

Ebuild Details

Version EAPI Keywords Slot
9999 8 ~amd64 0
View Raw Ebuild 
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit toolchain-funcs

DESCRIPTION="Purely functional dialect of Scheme"
HOMEPAGE="https://haltp.org/posts/owl.html
	https://gitlab.com/owl-lisp/owl/"

if [[ "${PV}" == *9999* ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://gitlab.com/owl-lisp/owl.git"
else
	SRC_URI="https://gitlab.com/owl-lisp/owl/-/archive/v${PV}/owl-v${PV}.tar.bz2"
	KEYWORDS="~amd64"
	S="${WORKDIR}/owl-v${PV}"
fi

LICENSE="MIT"
SLOT="0"

PATCHES=( "${FILESDIR}"/${PN}-0.2.1-make-no-test.patch )

src_prepare() {
	default

	# Skip "tests/char-ready.sh", "does not work in background subshell".
	rm tests/char-ready.sh || die
}

src_compile(){
	emake CC="$(tc-getCC)" CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" owl
}

src_install() {
	exeinto /usr/bin
	doexe "${S}"/bin/ol
	newexe "${S}"/bin/vm ovm

	doman "${S}"/doc/*.1

	einstalldocs
}

Inherited Eclasses

toolchain-funcs
git-r3