Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=9

inherit desktop

MYP=tkrev_${PV}
DESCRIPTION="Tcl/Tk-based graphical interface to CVS with Subversion support"
HOMEPAGE="https://tkcvs.sourceforge.io/"
SRC_URI="https://downloads.sourceforge.net/${PN}/${MYP}.tar.gz"

S="${WORKDIR}"/${MYP}
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"

DEPEND="dev-lang/tk"
RDEPEND="${DEPEND}
	dev-vcs/cvs
	dev-vcs/subversion
	sys-apps/diffutils
	dev-util/tkdiff"

src_prepare() {
	sed \
		-e "/set MANDIR/s/man man1/share man man1/" \
		-e "/set LIBDIR/s/lib/$(get_libdir)/" \
		-i doinstall.tcl || die
	sed \
		-e "/set TclRoot/s/lib/$(get_libdir)/" \
		-i tkrev/tkrev.tcl || die
	default
}

src_install() {
	# bug 66030
	unset DISPLAY
	./doinstall.tcl -nox "${D}"/usr || die

	# dev-tcktk/tkdiff
	rm "${D}"/usr/bin/tkdiff

	# Add docs...this is important
	dodoc {CHANGELOG,FAQ}.txt

	make_desktop_entry ${PN} TkRev "${EPREFIX}"/usr/$(get_libdir)/tkrev/bitmaps/ticklefish_med.gif
}