Gentoo Packages

kde-apps/kio-extras - 25.12.3 (gentoo)

Search

Package Information

Description:
KIO plugins present a filesystem-like view of arbitrary data
Homepage:
https://invent.kde.org/network/kio-extras
License:
GPL-2

Ebuild Details

Version EAPI Keywords Slot
25.12.3 8 ~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86 6
View Raw Ebuild 
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

ECM_HANDBOOK="optional"
ECM_TEST="true"
KFMIN=6.19.0
QTMIN=6.10.1
inherit ecm gear.kde.org optfeature xdg

DESCRIPTION="KIO plugins present a filesystem-like view of arbitrary data"
HOMEPAGE="https://invent.kde.org/network/kio-extras"

LICENSE="GPL-2" # TODO: CHECK
SLOT="6"
KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
IUSE="activities ios +man mtp nfs +libproxy openexr samba +sftp taglib X"

# requires running Plasma environment
RESTRICT="test"

DEPEND="
	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets,xml]
	>=dev-qt/qtsvg-${QTMIN}:6
	kde-apps/libkexiv2:6
	>=kde-frameworks/karchive-${KFMIN}:6
	>=kde-frameworks/kcmutils-${KFMIN}:6
	>=kde-frameworks/kcodecs-${KFMIN}:6
	>=kde-frameworks/kconfig-${KFMIN}:6
	>=kde-frameworks/kcoreaddons-${KFMIN}:6
	>=kde-frameworks/kdbusaddons-${KFMIN}:6
	>=kde-frameworks/ki18n-${KFMIN}:6
	>=kde-frameworks/kio-${KFMIN}:6
	>=kde-frameworks/kparts-${KFMIN}:6
	>=kde-frameworks/kservice-${KFMIN}:6
	>=kde-frameworks/kxmlgui-${KFMIN}:6
	>=kde-frameworks/solid-${KFMIN}:6
	>=kde-frameworks/syntax-highlighting-${KFMIN}:6
	activities? (
		>=dev-qt/qtbase-${QTMIN}:6[sql]
		kde-plasma/plasma-activities:6=
		kde-plasma/plasma-activities-stats:6
	)
	ios? (
		app-pda/libimobiledevice:=
		app-pda/libplist:=
	)
	libproxy? (
		>=kde-frameworks/knotifications-${KFMIN}:6
		net-libs/libproxy
	)
	mtp? ( >=media-libs/libmtp-1.1.16:= )
	nfs? ( net-libs/libtirpc:= )
	openexr? ( media-libs/openexr:= )
	samba? (
		>=kde-frameworks/kdnssd-${KFMIN}:6
		net-fs/samba[client]
		>=net-libs/kdsoap-2.2.0:=[qt6(+)]
		>=net-libs/kdsoap-ws-discovery-client-0.3.0
	)
	sftp? (
		dev-libs/qcoro
		net-libs/libssh:=[sftp]
	)
	taglib? ( >=media-libs/taglib-1.11.1:= )
	X? (
		x11-libs/libX11
		x11-libs/libXcursor
	)
"
RDEPEND="${DEPEND}
	!kde-apps/kio-extras:5[-kf6compat(-)]
	!kde-apps/kio-extras-kf5:5
	!<kde-frameworks/kio-5.116.0-r2:5
	!kde-frameworks/kio-trash-desktop-file:5
	>=kde-frameworks/kded-${KFMIN}:6
"
BDEPEND="man? ( dev-util/gperf )"

src_configure() {
	local mycmakeargs=(
		-DBUILD_ACTIVITIES=$(usex activities)
		$(cmake_use_find_package ios IMobileDevice)
		$(cmake_use_find_package ios PList)
		-DWITH_LIBPROXY=$(usex libproxy)
		$(cmake_use_find_package man Gperf)
		$(cmake_use_find_package mtp Libmtp)
		$(cmake_use_find_package nfs TIRPC)
		$(cmake_use_find_package openexr OpenEXR)
		$(cmake_use_find_package samba Samba)
		$(cmake_use_find_package sftp libssh)
		$(cmake_use_find_package taglib Taglib)
		-DWITHOUT_X11=$(usex !X)
	)
	ecm_src_configure
}

pkg_postinst() {
	optfeature "alternative filename search backend" sys-apps/ripgrep
	use samba && xdg_pkg_postinst
}

pkg_postrm() {
	use samba && xdg_pkg_postrm
}

USE Flags

activities
ios
man
❓ Default: Enabled (+)
mtp
nfs
libproxy
❓ Default: Enabled (+)
openexr
samba
sftp
❓ Default: Enabled (+)
taglib
X

Dependencies

DEPEND

	>=dev-qt/qtbase-6.10.1:6[dbus,gui,network,widgets,xml]
	>=dev-qt/qtsvg-6.10.1:6
	kde-apps/libkexiv2:6
	>=kde-frameworks/karchive-6.19.0:6
	>=kde-frameworks/kcmutils-6.19.0:6
	>=kde-frameworks/kcodecs-6.19.0:6
	>=kde-frameworks/kconfig-6.19.0:6
	>=kde-frameworks/kcoreaddons-6.19.0:6
	>=kde-frameworks/kdbusaddons-6.19.0:6
	>=kde-frameworks/ki18n-6.19.0:6
	>=kde-frameworks/kio-6.19.0:6
	>=kde-frameworks/kparts-6.19.0:6
	>=kde-frameworks/kservice-6.19.0:6
	>=kde-frameworks/kxmlgui-6.19.0:6
	>=kde-frameworks/solid-6.19.0:6
	>=kde-frameworks/syntax-highlighting-6.19.0:6
	activities? (
		>=dev-qt/qtbase-6.10.1:6[sql]
		kde-plasma/plasma-activities:6=
		kde-plasma/plasma-activities-stats:6
	)
	ios? (
		app-pda/libimobiledevice:=
		app-pda/libplist:=
	)
	libproxy? (
		>=kde-frameworks/knotifications-6.19.0:6
		net-libs/libproxy
	)
	mtp? ( >=media-libs/libmtp-1.1.16:= )
	nfs? ( net-libs/libtirpc:= )
	openexr? ( media-libs/openexr:= )
	samba? (
		>=kde-frameworks/kdnssd-6.19.0:6
		net-fs/samba[client]
		>=net-libs/kdsoap-2.2.0:=[qt6(+)]
		>=net-libs/kdsoap-ws-discovery-client-0.3.0
	)
	sftp? (
		dev-libs/qcoro
		net-libs/libssh:=[sftp]
	)
	taglib? ( >=media-libs/taglib-1.11.1:= )
	X? (
		x11-libs/libX11
		x11-libs/libXcursor
	)

RDEPEND

	>=dev-qt/qtbase-6.10.1:6[dbus,gui,network,widgets,xml]
	>=dev-qt/qtsvg-6.10.1:6
	kde-apps/libkexiv2:6
	>=kde-frameworks/karchive-6.19.0:6
	>=kde-frameworks/kcmutils-6.19.0:6
	>=kde-frameworks/kcodecs-6.19.0:6
	>=kde-frameworks/kconfig-6.19.0:6
	>=kde-frameworks/kcoreaddons-6.19.0:6
	>=kde-frameworks/kdbusaddons-6.19.0:6
	>=kde-frameworks/ki18n-6.19.0:6
	>=kde-frameworks/kio-6.19.0:6
	>=kde-frameworks/kparts-6.19.0:6
	>=kde-frameworks/kservice-6.19.0:6
	>=kde-frameworks/kxmlgui-6.19.0:6
	>=kde-frameworks/solid-6.19.0:6
	>=kde-frameworks/syntax-highlighting-6.19.0:6
	activities? (
		>=dev-qt/qtbase-6.10.1:6[sql]
		kde-plasma/plasma-activities:6=
		kde-plasma/plasma-activities-stats:6
	)
	ios? (
		app-pda/libimobiledevice:=
		app-pda/libplist:=
	)
	libproxy? (
		>=kde-frameworks/knotifications-6.19.0:6
		net-libs/libproxy
	)
	mtp? ( >=media-libs/libmtp-1.1.16:= )
	nfs? ( net-libs/libtirpc:= )
	openexr? ( media-libs/openexr:= )
	samba? (
		>=kde-frameworks/kdnssd-6.19.0:6
		net-fs/samba[client]
		>=net-libs/kdsoap-2.2.0:=[qt6(+)]
		>=net-libs/kdsoap-ws-discovery-client-0.3.0
	)
	sftp? (
		dev-libs/qcoro
		net-libs/libssh:=[sftp]
	)
	taglib? ( >=media-libs/taglib-1.11.1:= )
	X? (
		x11-libs/libX11
		x11-libs/libXcursor
	)

	!kde-apps/kio-extras:5[-kf6compat(-)]
	!kde-apps/kio-extras-kf5:5
	!<kde-frameworks/kio-5.116.0-r2:5
	!kde-frameworks/kio-trash-desktop-file:5
	>=kde-frameworks/kded-6.19.0:6

BDEPEND

man? ( dev-util/gperf )