net-libs/nDPI - 6.0 (gentoo)

Search

Install

Install this version:

emerge -a =net-libs/nDPI-6.0

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =net-libs/nDPI-6.0

Or alternatively:

emerge --autounmask-write -a =net-libs/nDPI-6.0

Package Information

Description:
Open Source Deep Packet Inspection Software Toolkit
Homepage:
https://www.ntop.org/
License:
LGPL-3+

Ebuild Details

Version EAPI Keywords Slot
6.0 8 ~amd64 ~x86 0/$(ver_cut 1)
View Raw Ebuild
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit autotools edo

DESCRIPTION="Open Source Deep Packet Inspection Software Toolkit"
HOMEPAGE="https://www.ntop.org/"
if [[ ${PV} == 9999 ]] ; then
	EGIT_REPO_URI="https://github.com/ntop/${PN}"
	inherit git-r3
else
	SRC_URI="https://github.com/ntop/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64 ~x86"
fi

LICENSE="LGPL-3+"
SLOT="0/$(ver_cut 1)"

DEPEND="dev-libs/json-c:=
	dev-libs/libgcrypt:=
	dev-libs/libgpg-error
	net-libs/libpcap"
RDEPEND="${DEPEND}"

src_prepare() {
	default

	eautoreconf
}

src_configure() {
	# "local" here means "local to the system", and hence means
	# system copy, not the bundled one.
	econf --with-local-libgcrypt
}

src_test() {
	local -x LD_LIBRARY_PATH="${S}/src/lib${LD_LIBRARY_PATH:+:${LD_LIBRARY_PATH}}"

	pushd tests || die

	edo ./do.sh
	edo ./do-unit.sh

	popd || die
}

Inherited Eclasses

edo

Dependencies

DEPEND

dev-libs/json-c:=
	dev-libs/libgcrypt:=
	dev-libs/libgpg-error
	net-libs/libpcap

RDEPEND

dev-libs/json-c:=
	dev-libs/libgcrypt:=
	dev-libs/libgpg-error
	net-libs/libpcap

Manifest for 6.0

Type File Size Source URLs
DIST nDPI-6.0.tar.gz 48649618 bytes https://github.com/ntop/nDPI/archive/6.0.tar.gz