Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

# Please keep a version around that matches Debian/Ubuntu for compatibility.
VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/tinc.asc
inherit systemd verify-sig

DESCRIPTION="tinc is an easy to configure VPN implementation"
HOMEPAGE="https://www.tinc-vpn.org/"
SRC_URI="
	https://www.tinc-vpn.org/packages/${P}.tar.gz
	verify-sig? ( https://www.tinc-vpn.org/packages/${P}.tar.gz.sig )
"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~arm ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="+lzo uml vde +zlib"

DEPEND="
	dev-libs/openssl:=
	lzo? ( dev-libs/lzo:2 )
	zlib? ( virtual/zlib:= )
"
RDEPEND="
	${DEPEND}
	vde? ( net-misc/vde )
"
BDEPEND="
	verify-sig? ( sec-keys/openpgp-keys-tinc )
"

src_configure() {
	econf \
		--enable-jumbograms \
		--disable-tunemu  \
		$(use_enable lzo) \
		$(use_enable uml) \
		$(use_enable vde) \
		$(use_enable zlib)
}

src_install() {
	emake DESTDIR="${D}" install
	dodir /etc/tinc
	dodoc AUTHORS NEWS README THANKS
	doconfd "${FILESDIR}"/tinc.networks
	newconfd "${FILESDIR}"/tincd.conf tincd
	newinitd "${FILESDIR}"/tincd-r1 tincd
	systemd_newunit "${FILESDIR}"/tincd_at.service "tincd@.service"
}