Gentoo Packages

sys-apps/ed - 1.22.4 (gentoo)

Search

Deprecated: This version is deprecated.

Reason: Doesn't work correctly on newer kernels/hardware. Events may go unreported if using sys-apps/edac-utils. See app-admin/rasdaemon's README for the technical details. Please migrate to app-admin/rasdaemon instead.

Deprecated by Sam James on 2022-12-29

Package Information

Description:
Your basic line editor
Homepage:
https://www.gnu.org/software/ed/
License:
GPL-2+

Ebuild Details

Version EAPI Keywords Slot
1.22.4 8 ~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos ~x64-solaris 0
View Raw Ebuild 
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/antoniodiazdiaz.asc
inherit edo toolchain-funcs unpacker verify-sig

MY_P="${PN}-${PV/_/-}"

DESCRIPTION="Your basic line editor"
HOMEPAGE="https://www.gnu.org/software/ed/"
SRC_URI="
	mirror://gnu/ed/${MY_P}.tar.lz
	https://download.savannah.gnu.org/releases/ed/${MY_P}.tar.lz
	verify-sig? (
		mirror://gnu/ed/${MY_P}.tar.lz.sig
		https://download.savannah.gnu.org/releases/ed/${MY_P}.tar.lz.sig
	)
"
S="${WORKDIR}"/${MY_P}

LICENSE="GPL-2+"
SLOT="0"
if [[ ${PV} != *_rc* ]] ; then
	KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos ~x64-solaris"
fi

BDEPEND="
	sys-apps/texinfo
	$(unpacker_src_uri_depends)
	verify-sig? ( sec-keys/openpgp-keys-antoniodiazdiaz )
"

src_unpack() {
	use verify-sig && verify-sig_verify_detached "${DISTDIR}"/${MY_P}.tar.lz{,.sig}
	unpacker "${DISTDIR}"/${MY_P}.tar.lz
}

src_configure() {
	edo ./configure \
		CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS}" \
		LDFLAGS="${LDFLAGS}" \
		CPPFLAGS="${CPPFLAGS}" \
		--bindir="${EPREFIX}/bin" \
		--prefix="${EPREFIX}/usr"
}